XSLT简单转换

Question

I have a very simple task, but I'm stuck here.

So, I have XML file like this:

<entries>
<entry>
    <field>field value</field>
</entry>
...
<entry>
    <field>field value</field>
</entry>

And it should be transformed with XSLT and looks like this:

<entries>
<entry field="field value">
...
<entry field="field value">
</entries>

Could you help me with template? Thanks a lot in advance.

Answer 1

This can be done with following XSLT:

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0">
<xsl:output method="xml" omit-xml-declaration="yes" encoding="UTF-8" 
    indent="yes" />
<xsl:strip-space elements="*"/>
  <xsl:template match="/">
    <xsl:apply-templates/>
  </xsl:template>
  <xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="entry">
    <xsl:copy>
        <xsl:attribute name="field">
          <xsl:value-of select="field"/>
        </xsl:attribute> 
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="field"/>
</xsl:transform>

When applied to the example input XML

<entries>
  <entry>
    <field>field value 1</field>
  </entry>
  <entry>
    <field>field value 2</field>
  </entry>
</entries>

the following output is produced:

<entries>
 <entry field="field value 1"/>
 <entry field="field value 2"/>
</entries>

The template matching entry <xsl:template match="entry">

copies the entry and adds as attribute field the value of the field node:

<xsl:copy>
  <xsl:attribute name="field">
    <xsl:value-of select="field"/>
  </xsl:attribute> 
  <xsl:apply-templates/>
</xsl:copy>

and the template matching field <xsl:template match="field"/> is empty and removes the field nodes.