有什么方法可以使用xpath过滤/处理文字结果元素？

Question

I'm working on a stylesheet to transform tables similar to IETF (ie xhtml) tables, but column-oriented, to xsl-fo.

One of the first steps is to transform <col/> tags to <fo:table-column/> tags. Unfortunately for some reason the authors of the XSL 1.1 spec didn't provide a way to transfer all attributes automatically from <fo:table-column/> to the table-cells in the corresponding column, and the attributes (with the exception of width) don't apply automatically, either (really dumb design decision, in my opinion -- here is one of the Antenna House developers complaining about the same thing in 2001! ). Inheritance doesn't apply, either, as <fo:table-column/> doesn't have any children.

This leaves me with the task of figuring out what formatting attributes have been set for each column and applying them by hand to the appropriate table-cells. How best to do that, though? One thought I had was to place all the <fo:table-column/> nodes into a variable, but then how would I use xpath to process these nodes? The other thought is there must be a way to do this using a temporary result tree, but have never used anything like this and am clueless about whether not this is possible, and if it is, how one would work with a temporary result tree. I'm posting this question with labels XSLT 1.0 and XSLT 2.0 just to see if there is an answer, but I'm really constrained to using XSLT 1.0 for this problem.

Edit: Someone requested a concrete example. A source document fragment might look something like this:

<table>
  <col width="33%" font-weight="bold" border="1pt solid black"/>
  <col width="34%" span="2" color="red" background-color="gray"/>
  <col font-style="italic" align="center" background-color="yellow"/>
  <tr><td>A</td><td>B</td><td>C</td><td>D</td></tr>
  <tr><td>dog</td><td>cat</td><td>mouse</td><td>elephant</td></tr>
  ...
</table>

ie a standard xhtml table, except with some attributes that would normally be represented using the style attribute.

Then natural translation would be

<table> -->  <fo:table>
<col/>  -->  <fo:table-column/>
<tr>    -->  <fo:table-row>
<td>    -->  <fo:table-cell>

However, there is a problem with this, namely none of the attributes in <table-column/> are automatically applied to the table cells in the corresponding column unless you specifically request that they be invoked using the from-table-colum() function (with the exception of width which is automatically applied). So, for example, for a table cell in the 3rd column of the table I would need to output the fo like this:

<fo:table-cell color="from-table-column()" background-color="from-table-column()>

and for a table cell in the 4th column I would need to output

<fo:table-cell font-style="from-table-column()" align="from-table-column()" background-color="from-table-column()>

The question is how do you know which attributes to look for for the table-cells in a particular column?

Answer 1

Well with XSLT 1.0 a variable containing result nodes is a result tree fragment, to convert it into a node set to be apply to apply XPath or process the nodes further you would use exsl:node-set or similar eg

<xsl:variable name="v1-rtf">
  <fo:table-column>...</fo:table:column>
</xsl:variable>

<xsl:variable name="v1-ns" xmlns:exsl="http://exslt.org/common" select="exsl:node-set($v1-rtf)"/>

<xsl:apply-templates select="$v1-ns/fo:table-column"/>

The only difference in XSLT 2.0 is that you don't need the exsl:node-set function and its conversion operation, you can use any variable with temporary trees directly eg

<xsl:variable name="v1">
  <fo:table-column>...</fo:table:column>
</xsl:variable>

<xsl:apply-templates select="$v1/fo:table-column"/>

Answer 2

Caveat : I know nothing about XSL-FO; this is just something for you to use as a starting point.

The way I understood your question, you want each table-cell to have the same list of attributes as the corresponding col in the source document. This would have been very easy to accomplish by looking at the position of the currently processed td and using that to look up the col at the same relative position. However, since some of the col elements have a span attribute, this is not as easy as that.

The solution I would suggest is to start by "enumerating" the col elements, so that there are exactly as many of them as there are columns. With this in place, we can proceed as planned.

The following stylesheet:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="columns">
    <xsl:for-each select="/table/col">
        <xsl:call-template name="replicate">
            <xsl:with-param name="n">
                <xsl:choose>
                    <xsl:when test="@span">
                        <xsl:value-of select="@span"/>
                    </xsl:when>
                    <xsl:otherwise>1</xsl:otherwise>
                </xsl:choose>
            </xsl:with-param>
        </xsl:call-template>
    </xsl:for-each>
</xsl:variable>

<xsl:template match="/table">
    <fo:table>
        <xsl:apply-templates/>  
    </fo:table>
</xsl:template>

<xsl:template match="tr">
    <fo:table-row>
        <xsl:apply-templates select="td"/>
    </fo:table-row>
</xsl:template>

<xsl:template match="td">
    <xsl:variable name="i" select="position()" />
    <fo:table-cell>
        <xsl:for-each select="exsl:node-set($columns)/col[$i]/@*[not(name()='width' or name()='span')]">
            <xsl:attribute name="{name()}">from-table-column()</xsl:attribute>
        </xsl:for-each>
        <xsl:apply-templates/>  
    </fo:table-cell>
</xsl:template>

<xsl:template name="replicate">
    <xsl:param name="n"/>
    <xsl:if test="$n">
        <xsl:copy-of select="."/>
        <xsl:call-template name="replicate">
            <xsl:with-param name="n" select="$n - 1"/>
        </xsl:call-template>        
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

when applied to your input example, will produce the following result :

<?xml version="1.0" encoding="utf-8"?>
<fo:table xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:table-row>
      <fo:table-cell font-weight="from-table-column()" border="from-table-column()">A</fo:table-cell>
      <fo:table-cell color="from-table-column()" background-color="from-table-column()">B</fo:table-cell>
      <fo:table-cell color="from-table-column()" background-color="from-table-column()">C</fo:table-cell>
      <fo:table-cell font-style="from-table-column()" align="from-table-column()" background-color="from-table-column()">D</fo:table-cell>
   </fo:table-row>
   <fo:table-row>
      <fo:table-cell font-weight="from-table-column()" border="from-table-column()">dog</fo:table-cell>
      <fo:table-cell color="from-table-column()" background-color="from-table-column()">cat</fo:table-cell>
      <fo:table-cell color="from-table-column()" background-color="from-table-column()">mouse</fo:table-cell>
      <fo:table-cell font-style="from-table-column()" align="from-table-column()" background-color="from-table-column()">elephant</fo:table-cell>
   </fo:table-row>
</fo:table>

This is assuming the table cells themselves do not have spans; otherwise this could get much more complex.