如何在 Google 表格上按组分隔人员

Question

I hope you are doing great. I hope someone could help with this.

I have 2 groups of people "A" and "B"

both groups work on the same tasks

but I would like to get them with an "@" on a different sheet; separated into groups (group A and B) and both groups mixed (general)

Does anyone know how can I automatically separate them into groups A and B? I was wondering if I could use a match formula and an if formula, I tried to do it but had no success. The task can vary but no the group so the best would be to get formula or any way to automatically add thee people per group.

As an additional info I used this formula to get the general result: =IFNA(JOIN(", ";QUERY('Sheet 1':A3;E12;"select A where B = TRUE";0));"")

This is the Google sheet I've been using to try to do this:

https://docs.google.com/spreadsheets/d/14fdQJcIuqFTfo8upNOtALk0vhQYjSM0d8nYRML4amuM/edit?usp=sharing

Any help is so appreciated. Thank you!

Answer 1

B10:

=ARRAYFORMULA(TRIM(FLATTEN(QUERY(TRANSPOSE(XLOOKUP(SPLIT(B3:B6; "@ "); 
 IF('Sheet 3'!B3:B12; 'Sheet 3'!A3:A12; ); "@"&'Sheet 3'!A3:A12;;; 1));;9^9))))

B17:

=ARRAYFORMULA(TRIM(FLATTEN(QUERY(TRANSPOSE(XLOOKUP(SPLIT(B3:B6; "@ "); 
 IF('Sheet 3'!C3:C12; 'Sheet 3'!A3:A12; ); "@"&'Sheet 3'!A3:A12;;; 1));;9^9))))

Answer 2

Paste this formulas
in Sheet2 cells A2 , A9 , A16

=ArrayFormula(IF(SUMPRODUCT('Sheet 1'!B3:E)=0;;IFERROR({ "General"\ " "; 
                 TRANSPOSE({ 'Sheet 1'!B2:E2;BYCOL(
                                   IF('Sheet 1'!B3:E12<>TRUE;;"@"&'Sheet 1'!A3:A12); 
                                   LAMBDA(v; TEXTJOIN(" "; 1;v)))})};"")))

=ArrayFormula(IFERROR({ SPLIT('Sheet 3'!B1&" "&'Sheet 3'!B2&", " ; ",");
                TRANSPOSE({  'Sheet 1'!B2:E2;
                             BYCOL(IF(FILTER('Sheet 1'!B3:E; 'Sheet 3'!B3:B=TRUE)<>TRUE;;"@"&'Sheet 1'!A3:A); 
                             LAMBDA(v; TEXTJOIN(" "; 1;v)))}) };""))

=ArrayFormula(IFERROR({ SPLIT('Sheet 3'!B1&" "&'Sheet 3'!C2&", " ; ",");
                TRANSPOSE({  'Sheet 1'!B2:E2;
                             BYCOL(IF(FILTER('Sheet 1'!B3:E; 'Sheet 3'!C3:C=TRUE)<>TRUE;;"@"&'Sheet 1'!A3:A); 
                             LAMBDA(v; TEXTJOIN(" "; 1;v)))}) };""))

Functions used
ARRAYFORMULA - TRANSPOSE - BYCOL - IF - LAMBDA - TEXTJOIN

Answer 3

Simply replace the opposing group in general category using regex :

For group A, replace B:

=ARRAYFORMULA(REGEXREPLACE(B3:B6,"@"&JOIN("( |$)|@",FILTER(Sheet3!A3:A12,Sheet3!C3:C12)),))

where B3:B6 is the General category's values column and Sheet3 contains Groups.

This creates a regex like

@P1( |$)|@P2( |$)|@P5( |$)|@P6( |$)|@P8( |$)|@P10

Which is @ followed by any group P1 and followed by a space or end of string ( |$) . For this to work properly, avoid regex meta characters in People names.