unexpected logiclib behavior when testing string returned by system plugin

Question

I am getting system information via the System plugin by using code similar to the answer to my previous question . The API function is very similar except that it returns (or not) a wide char string.

While using that script on a computer that is member of a domain, I cannot understand why the logiclib test always pass in the ${else} branch of the test. The following capture shows that $1 is not null:

While reading more the NetGetDCName reference I think that it would be preferable to check the function returned value instead of the wide char string pointer. I am a bit confused, why does my ${If} 0 <> $1 always fails? I have checked on a virtual machine not member of a domain that $1 equals 0 in this case. I suppose then that the ${IfThen} test to free the memory is wrong too.

Here is the sample code:

!include "logiclib.nsh"
outfile "hello2.exe"

!define DEBUG `System::Call kernel32::OutputDebugString(ts)`

section

    Call GetDCName
    pop $0

    Messagebox MB_OK "DCName=$0"

sectionEnd

Function GetDCName
    ;Push the domain controler name to the stack (or an empty string if no dc)
    push $0
    push $1
    push $2
    System::Call "netapi32::NetGetDCName(i0, i0, *w 0 r1) i.r2"
    Dumpstate::debug
    ${If} 0 <> $1
        ${debug} "copy $1"
        StrCpy $0 $1
    ${else}
        ${debug} "copy empty string"
        StrCpy $0 ""
    ${endif}
    ${IfThen} $1 <> 0 ${|} System::Call "netapi32::NetApiBufferFree(ir1)" ${|}
    Pop $2
    Pop $1
    Exch $0
FunctionEnd

Edit: thanks to Anders, here is the corrected function:

Function GetDCName
    ;Push the domain controler name to the stack (or an empty string if no dc)
    push $0
    push $1
    push $2
    System::Call "netapi32::NetGetDCName(i0, i0, *i 0 r1) i.r2" ;do not convert r1 to wchar, keep the pointer to free it
    ${If} $2 = 0
        System::Call "*$1(&w${NSIS_MAX_STRLEN} .r0)"        ;get the wchar from the pointer
        ${IfThen} $1 <> 0 ${|} System::Call "netapi32::NetApiBufferFree(ir1)" ${|}  ;free the pointer
    ${else}
        StrCpy $0 ""
    ${endif}
    Pop $2
    Pop $1
    Exch $0
FunctionEnd

Answer 1

The <> operator is for numbers, not strings. This is not your only problem though; * can (normally) only be used with i , not t / m / w . The t / m / w types convert to and from C style strings but in your case you need the actual memory address since you have to pass it to the free function.

You need to pass *i0r1 to NetGetDCName, then if $2 is 0 then you can extract the string with the struct syntax ( *$1(&w${NSIS_MAX_STRLEN}.r5) or *$1(w.r5) ) and finally pass $1 untouched to the free function...