使用VB删除ActiveDirectory中的主目录

Question

我想使用VB在AD中搜索禁用的帐户（超过90天并删除其主目录。以下脚本可以正常运行，但不能递归 :(

任何人都可以帮助使其正常工作吗？ 他的任何帮助将不胜感激:)

Option Explicit

Dim objOU, objUser, objFSO, strHomeDirectory, objTextFile

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objOU = GetObject("LDAP://OU=users,DC=corp,DC=contoso,DC=com")

objOU.Filter = Array("user")

For Each objUser In objOU
if ( objuser.useraccountcontrol = 514 Or objuser.useraccountcontrol = 66050 ) And DateDiff("d", objUser.WhenChanged, Now) > 90 Then 
    ' Retrieve home directory.
    strHomeDirectory = objUser.homeDirectory
    ' Replace %username% with value of sAMAccountName attribute.
     strHomeDirectory = Replace(strHomeDirectory, "%username%", objUser.sAMAccountName)
    ' Delete the folder.
     objFSO.DeleteFolder strHomeDirectory
else
wscript.sleep 100
End If
Next

Answer 1

通常，您可以使用LDAP查询来执行此操作 。 如果您会原谅这个无耻的插件，我不久前就为AD查询编写了一个类，以简化此类任务。 您可以将代码复制/粘贴到脚本中，然后像这样使用它：

Set fso = CreateObject("Scripting.FileSystemObject")

Set qry = New ADQuery
qry.Filter = "(&(objectClass=User)(objectCategory=Person)" & _
             "(userAccountControl:1.2.840.113556.1.4.803:=2))"
qry.Attributes = Array("sAMAccountName", "homeDirectory", "whenChanged")

Set rs = qry.Execute

If Not rs Is Nothing Then
  Do Until rs.EOF
    If DateDiff("d", rs.Fields("whenChanged").Value, Now) > 90 Then
      homedir = rs.Fields("homeDirectory").Value
      homedir = Replace(homedir, "%username%", rs.Fields("sAMAccountName").Value)
      If fso.FolderExists(homedir) Then fso.DeleteFolder homedir
    End If
    rs.MoveNext
  Loop
  rs.Close
End If