Windows批处理-将x数量的文件夹+内容移动到另一个文件夹

Question

我正在清理和整理我的NAS文件夹。

但是，我的文件夹中有超过1800+个文件夹，我需要将此文件夹分成18个文件夹，每个文件夹最多包含100个文件夹。 它们移动到的文件夹的名称无关紧要，但在顶层应该是连续的。 所有文件夹内容都应一起移动。

另外，我需要一个批处理文件，它也可以逆转此情况。

之所以需要这样做，是因为我用于索引和组织我的文件夹和文件夹内容的程序无法轻松处理包含100个以上文件夹的文件夹。

我已经尝试过自己，但是最终完全愚弄了它。

Answer 1

像这样吗

@ECHO OFF

SET destination=c:\temp\
SET source=c:\windows\system32\
SET dcount=0
SET fcount=0
SETLOCAL ENABLEDELAYEDEXPANSION

MKDIR %destination%dir%dcount%


FOR /f "tokens=*" %%f in ('DIR /b /s /a:d "%source%*"') do (
  SET str=%%f
  SET str=!str:%source%=!
  MKDIR %destination%dir!dcount!\!str!
  COPY %%f %destination%dir!dcount!\!str! 1> NUL
  SET /a fcount=!fcount!+1
  IF !fcount! EQU 100 (
    SET fcount=0
    SET /a dcount=!dcount!+1
    MKDIR %destination%dir!dcount!
  )
)

ECHO DONE.

显然，源和目标将需要更改，并且没有尝试进行健全性检查或因错误而正常失败...

编辑：

第一个版本递归地降级所有子目录，并将每个子目录移到新结构中-基本破坏了它们的内部嵌套和组织。 第二部分保留了嵌套在源目录的直接子目录内的子目录的内部结构。

@ECHO OFF

SET destination=c:\temp\
SET source=c:\windows\system32\
SET dcount=0
SET fcount=0
SETLOCAL ENABLEDELAYEDEXPANSION

MKDIR %destination%dir%dcount%


FOR /f "tokens=*" %%f in ('DIR /b /a:d "%source%*"') do (
  MKDIR %destination%dir!dcount!\%%f
  XCOPY %source%%%f %destination%dir!dcount!\%%f /e /y 
  SET /a fcount=!fcount!+1
  IF !fcount! EQU 100 (
    SET fcount=0
    SET /a dcount=!dcount!+1
    MKDIR %destination%dir!dcount!
  )
)

ECHO DONE.

Answer 2

这在我的有限测试中有效，并创建了UNDO.BAT来将文件夹还原到原来的位置。 自己进行测试，以确保它可以满足您的需求。

值num是每个顶级文件夹中所需的文件夹数

f用于创建保存文件夹-001、002、003等

在要移动所有子目录的文件夹中启动它。

@echo off
setlocal enabledelayedexpansion
set num=100
set c=0
set f=1001
set folder=%f:~-3%
del undo.bat 2>nul
for /f "delims=" %%a in ('dir /a:d /o:n /b') do (
set /a c=c+1
   md !folder! 2>nul
   move "%%a" !folder!
   echo move "!folder!\%%a" "%cd%" ^& rd !folder! 2^>nul >>undo.bat
    if !c! EQU %num% (
      set c=0
      set /a f=f+1
      set folder=!f:~-3!
    )
)