如何使用pl / sql进行批处理操作

Question

我必须为许多表添加主键，并且我从stackoverflow获得了以下脚本（用于一个表）：

ALTER TABLE table1 ADD ID NUMBER(12);
CREATE SEQUENCE table1Seq START WITH 1;
UPDATE table1 SET table1ID = table1Seq.NEXTVAL;
ALTER TABLE table1 ADD PRIMARY KEY (ID);
CREATE OR REPLACE TRIGGER table1PKSet
BEFORE INSERT ON table1
FOR EACH ROW
BEGIN
  :NEW.ID := table1Seq.NEXTVAL;
END;
/

但是，现在我对用户的所有表都执行了相同的操作。

所以我想知道是否可以使用pl / sql循环用户的所有表，并执行上述操作？

Answer 1

我只想说这很毛病，然后再开始。 如果要创建自动执行数据库创建的脚本，那么我将放弃以下查询，而直接执行复制/粘贴操作，因为这太可怕了，它不属于您的数据库部署脚本。

查询

DECLARE
    CURSOR TABLES IS SELECT * FROM USER_TABLES
                     WHERE 0 = (SELECT COUNT(*)
                                FROM USER_CONSTRAINTS
                                WHERE USER_CONSTRAINTS.TABLE_NAME = USER_TABLES.TABLE_NAME 
                                AND USER_CONSTRAINTS.CONSTRAINT_TYPE = 'P'
                               );
BEGIN
    FOR T IN TABLES LOOP
        EXECUTE IMMEDIATE 'ALTER TABLE '||T.TABLE_NAME||' ADD ID NUMBER(12)';
        EXECUTE IMMEDIATE 'CREATE SEQUENCE '||T.TABLE_NAME||'Seq START WITH 1';
        EXECUTE IMMEDIATE 'UPDATE '||T.TABLE_NAME||' SET ID = '||T.TABLE_NAME||'Seq.NEXTVAL';
        EXECUTE IMMEDIATE 'ALTER TABLE '||T.TABLE_NAME||' ADD PRIMARY KEY (ID)';
        EXECUTE IMMEDIATE 'CREATE OR REPLACE TRIGGER '||T.TABLE_NAME||'PKSet '||CHR(10)
                          ||'BEFORE INSERT ON '||T.TABLE_NAME||' '||CHR(10)
                          ||'FOR EACH ROW '||CHR(10)
                          ||'BEGIN '||CHR(10)
                          ||':NEW.ID := '||T.TABLE_NAME||'Seq.NEXTVAL; '||CHR(10)
                          ||'END; ';
    END LOOP;
END;
/

这是做什么的？

基本上，它获取表列表并动态构建SQL以执行涉及的各种任务。 EXECUTE IMMEDIATE在构建SQL的字符串中执行它。 CHR(10)讨厌程度是换行符。 我想在其中添加空格，因为我不知道将其留空会如何影响Oracle的解析。 请注意，在某些地方，我们将表名直接连接到其他文本，以生成序列或PK约束名称。

如果您在创建过程中引用了表名并且使用了小写字母，则可能会或不会出错。 如果确实出错，请记住每个语句都包含一个提交。 错误将意味着该过程完成了一半。 如果架构不是当前用户，它也会失败。 （您需要将USER_TABLES更改为ALL_TABLES并在where子句中添加一个适当的过滤器，并在构建SQL使其可在其他模式上使用时在表名之前添加模式。）

实际可用的SQLFiddle： http ://sqlfiddle.com/#!4/b67fc/1（我不敢相信这实际上在SQLFiddle上有效。）在这种情况下，由于SQL，我们感兴趣的查询已在架构定义中结束小提琴只允许在查询中使用SELECT 。

祝好运。 您将需要它。 不要用脚开枪射击自己。