绘制不同数据文件的中间值（使用gnuplot）

Question

我有4个不同的数据文件（用于季节），并且已经设法用中位数和东西制作了箱形图。

但是现在，我想用简单的线条来显示季节变化。 我希望gnuplot绘制4个季节的中值（也许是夸脱或标准差），并通过线点将它们连接起来。

值位于一列的4个单独的数据文件中-每列有一个中位数（和四分位数...）。 我也想忽略前几项。

我已经尝试过命令stats但是我总是在这里得到一个错误：

stats 'VARIANTE 1\Habitate\Äschen\Vergleich\FRU\WUA_Vergleich.dat' u 2 every ::5 label  "Ist_FRU"
stats 'VARIANTE 1\Habitate\Äschen\Vergleich\SOM\WUA_Vergleich.dat' u 2 every ::5 label "Ist_SOM"
stats 'VARIANTE 1\Habitate\Äschen\Vergleich\HER\WUA_Vergleich.dat' u 2 every ::5 label "Ist_HER"
stats 'VARIANTE 1\Habitate\Äschen\Vergleich\WIN\WUA_Vergleich.dat' u 2 every ::5 label "Ist_WIN"

我在这里定义了特殊的xtics ：

set xtics ("Fru" 1, "Som" 2, "Her" 3, "Win" 4) scale 0.0  out font ",9"

然后想绘制该数据：

plot \
 (1):median_Ist_FRU notitle linestyle 1, \
 (2):median_Ist_SOM notitle linestyle 1, \
 (3):median_Ist_HER notitle linestyle 1, \
 (4):median_Ist_WIN notitle linestyle 1 

我想我不太了解命令stats或无法正确plot命令，对于有经验的用户来说，解决方案可能非常简单-但我尝试了许多不同的方法，但没有任何效果。

提前致谢！

Answer 1

您为stats命令使用了错误的语法（如果提供了错误消息，将会很有帮助）。 您必须使用name ，其余的是方便的：

tmpl = 'VARIANTE 1\Habitate\Äschen\Vergleich\%s\WUA_Vergleich.dat'
stats sprintf(tmpl, "FRU") u 2 every ::5 name "Ist_FRU_"
stats sprintf(tmpl, "SOM") u 2 every ::5 name "Ist_SOM_"
stats sprintf(tmpl, "HER") u 2 every ::5 name "Ist_HER_"
stats sprintf(tmpl, "WIN") u 2 every ::5 name "Ist_WIN_"

绘图部分有些棘手：

reset
# these are some test values
Ist_FRU_median = 1
Ist_SOM_median = 0.5
Ist_HER_median = 1.5
Ist_WIN_median = 1.2

set xtics ("Fru" 1, "Som" 2, "Her" 3, "Win" 4) scale 0.0
quartil="FRU SOM HER WIN"
set samples 4
set xrange[0.8:4.2]
plot '+' using ($0+1):(value('Ist_'.word(quartil, int($0+1)).'_median')) with linespoints title ''

脚本的粗略解释：通常，gnuplot只有在点出现在同一数据文件中时才能将点与线连接起来。

为了模拟这一点，我使用了特殊文件名+ ，该文件名会在指定范围内生成大量样本（必须设置xrange才能使用+ ）。 我使用了四个样本（ set samples 4 ），可以在using语句中using $ 0（或column（0））访问当前样本的编号。 样本数从0到3 。

quartil包含四个单词，稍后将其提取以构造变量名称。 第一个单词的索引为1 ，因此我使用word(quartil, $0+1) 。

如果将变量名称为字符串，则可以通过value(string)访问其值。

测试数据的结果是：