鼠标坐标到Firemonkey TMemo组件中的插入位置

Question

处理Firemonkey上的鼠标/拖放事件TMemo Component提供了Mousecursor坐标。 有没有一种方法可以根据鼠标坐标来计算CaretPosition？

我想将文本拖到TMemo中，并且此文本应插入到当前的MouseCoordinates中。

Answer 1

尝试调用GetPointPosition 。

不幸的是，这似乎已从XE3中的TMemo中删除。 作为一种快速而肮脏的解决方法，您可以尝试以下操作：

function GetPointPosition(Memo: TMemo; Pt: TPointF; RoundToWord: Boolean = False): TCaretPosition;
var
  I, LPos: Integer;
  Rgn: TRegion;
begin
  Result.Line := -1;
  Result.Pos := -1;
  for I := 0 to Memo.Lines.Count - 1 do
  begin
    if Memo.Lines.Objects[I] is TTextLayout then
    begin
      LPos := TTextLayout(Memo.Lines.Objects[I]).PositionAtPoint(Pt, RoundToWord);
      if LPos >= 0 then
      begin
        if LPos > 0 then
        begin
          Rgn := TTextLayout(Memo.Lines.Objects[I]).RegionForRange(TTextRange.Create(LPos, 1), RoundToWord);
          if (Length(Rgn) > 0) and (Rgn[0].Top > Pt.Y) then
            Dec(LPos);
        end;
        Result.Line := I;
        Result.Pos := LPos;
        Break;
      end;
    end;
  end;
end;

Answer 2

适用于使用RTTI的XE10的解决方案：

procedure TMyForm.MemoMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Single);
var Obj: IControl;   
    af: TPointf;
    cp: TCaretPosition;
    aName: string;
    LVar: TStyledMemo;
    LClass: TRttiInstanceType;
    aLines: TObject;
    aMethod: TRttiMethod;
    aValue: TValue;
    pointValue, boolValue: TValue;
begin
   af := TPointF.Create(Panel1.Position.X + X, panel4.Height + Y);
   Obj := ObjectAtPoint(ClientToScreen(af));

   if Assigned(Obj) then
   begin
       LVar := TStyledMemo(Obj);
       LClass := LContext.GetType(TStyledMemo) as TRttiInstanceType;
       aLines := LClass.GetField('FLineObjects').GetValue(LVar).AsObject;

       af := TPointF.Create(X,Y);
       pointValue := TValue.From<TPointF>(af);  
       boolValue := TValue.From<Boolean>(false);

       LClass := LContext.GetType(aLines.ClassType) as TRttiInstanceType;
       aMethod := LClass.GetMethod('GetPointPosition');
       aValue := aMethod.Invoke(aLines, [pointValue, boolValue]);

       cp := aValue.AsType<TCaretPosition>;
   end;
end;