SAS：单个观测值的AVG（）

Question

我正在尝试获取特定变量列表的模式。 当模式不是唯一的时，我想返回模式的平均值，以使要获取模式的子查询（在较大的查询中）不会返回两个值。 但是，当模式为唯一时，由于某种原因，平均查询将返回缺少的值。

我有以下示例数据：

data have;
input betprice;
datalines; 
    1.05
    1.05
    1.05
    6
    run;
    PROC PRINT; RUN;

proc sql;
select avg(betprice) 
    from
    (select betprice, count(*) as count_betprice from have group by betprice) 
    having count_betprice = max(count_betprice);
quit;

如果我在betprice字段中添加更多观察值，以致于模式不是唯一的，则我确实会返回平均值。

data have;
input betprice;
datalines; 
    1.05
    1.05
    1.05
    6
    6
    6

run;
PROC PRINT; RUN;

如何更改此查询，以便始终返回模式或两个最频繁值的平均值。

感谢您对此的任何帮助。

Answer 1

您正在使用SAS，为什么不让SAS计算统计信息，因为这很擅长...

ods output modes=want;
proc univariate data=have modes;
var betprice;
run;
ods output close;

proc means data=want;
var mode;
output out=final(keep=betprice) mean=betprice;
run;

这不会花很长时间，对于另一个程序员来说您正在做什么更加清楚，并且非常容易编写代码。 如果您不采用这些模式的均值，则可以一步完成。

Answer 2

首先，请注意，在使用外部查询时，您没有分组依据语句，但是使用了Haveing子句。 这不行。

这是一个可行的解决方案：

proc sql;
    create view WORK.V_BETPRICE_FREQ as
    select betprice, count(*) as count_betprice
    from HAVE
    group by betprice
    ;

    select avg(betprice) as final_betprice
    from WORK.V_BETPRICE_FREQ
    where count_betprice = (select max(count_betprice) from WORK.V_BETPRICE_FREQ)
    ;
quit;

我在这里使用了一个视图来防止代码重复。 如果视图中的查询在CPU方面确实是一项繁重的操作，则您可能希望将其替换为物理表。

编辑作为反馈：我相信您在查询中遇到了困难，因为在外部查询中您需要：
1.过滤后，对所有记录执行聚合功能。
2.在过滤器中使用聚合函数。
如果没有group by语句，则不能执行第一个操作，而如果没有group by语句，则不能执行第二个操作。

因此，最终结果中，我将第一个保留在外部查询中，而在另一个子查询中执行第二个。

Answer 3

这很难，在使用SAS 12年后，我不记得曾经/曾经在没有GROUP BY的情况下使用HAVING，我想它会产生意想不到的结果。

因此，对于单个查询，我的解决方案不是很好，因为它进行了两次分组。

单个查询版本：

proc sql;
select avg(betprice) 
    from ( select
                  betprice
                , count(*) as count_betprice
                from work.have
                group by betprice) /* first summary */
    where count_betprice
                = select max(count_betprice)
        from
          (select
                  betprice
                , count(*) as count_betprice
                from work.have
                group by betprice) /* same summary here */;
quit;

使用中间表（或视图，如果需要）而不是相同的子查询进行一些简化：

proc sql;
create table work.freq_sum
        as select
                betprice
                , count(*) as count_betprice
                from work.have
                group by betprice
;
select avg(betprice) 
    from work.freq_sum
    where count_betprice
                = select max(count_betprice) from work.freq_sum;
quit;

请注意，您可以通过PROC MEANS计算诸如MODE和MEDIAN之类的统计信息：

proc means data=have n mean mode median;
var betprice;
run;