如何在SAS中导入包含重复列名的csv文件

Question

我想导入SAS中具有重复列名的CSV文件。 例

名称abc abc def def

是我文件中的列名。

当我尝试在SAS中导入文件时，它会自动将变量重命名为var1，var2等。

我想保留原始的列名。 我怎样才能做到这一点？

Answer 1

您可以通过几种不同的方式进行操作。 进行示例的最简单方法如下所示：

data want;
infile datalines dlm=',';
input name $ abc1-abc2 def1-def2;
datalines;
John,1,2,3,4
Jack,4,5,6,7
;;;;
run;

proc print data=want;
run;

显然1-2可以变成1-35或其他。

如果您的数据比使用交错变量更复杂，我建议您仅读入标题行，对其进行转置并从中构造一个输入语句。

data varnames; *this dataset reads the header in only - use infile with obs option for actual csv;
input varname $ @@;
order+1; *so we can get back to proper order;
datalines;
Name abc abc def def
;;;;
run;

proc sort data=varnames; *sort by varname;
by varname;
run;

data input_statement;
set varnames;
by varname;
if first.varname then counter=0;
if not (first.varname and last.varname) then do; *if this is not the only varname with same varname;
 counter+1;                          *increment counter;
 varname=cats(varname,counter);      *append counter to varname;
end;
run;

proc sort data=input_statement;   *back to correct order;
by order;
run;

proc sql;   *select the new names into a macro variable;
select varname into :namelist separated by ' ' from input_statement;
quit;

data want;  *input them;
infile datalines dlm=',';
input (&namelist) ($);  *here I just make them all CHAR.  If you have all NUM except the name var, 
                         you could leave name out of your datasets and include it separately.;
datalines;
John,1,2,3,4
Jack,4,5,6,7
;;;;
run;

Answer 2

从文档看来，您将变量名放在第一行并使用GETNAMES=yes 。

proc import datafile="C:\temp\test.csv"
   out=shoes
   dbms=csv
   replace;
   getnames=yes;
run;

proc print;
run;

Answer 3

SAS数据集中不能有重复的列名。 您必须将它们重命名为某种名称。 如果您不喜欢proc import功能，则可以通过proc datasets手动重命名它们。

proc datasets;
    modify <dataset>;
    rename var1=name var2=abc1 var3=abc2 var4=def1 var5=def2;
quit;