批处理文件 (windows cmd.exe) 测试目录是否为链接（符号链接）

Question

我刚刚了解到这是一种在批处理文件中测试文件是否为链接的方法：

dir %filename% |  find "<SYMLINK>" && (
   do stuff
)

我如何做一个类似的技巧来测试一个目录是否是一个符号链接。 仅将<SYMLINK>为<SYMLINKD>是<SYMLINKD> ，因为dir %directoryname%列出了目录的内容，而不是目录本身。

似乎我需要某种方式让 dir 告诉我有关目录的信息，就像我在父目录中询问一样。 （就像ls -d在 unix 中所做的那样）。

或者任何其他测试目录是否是符号链接的方法？

谢谢！

Answer 1

你有三种方法

解决方案 1：fsutil 重新解析点

将符号链接/连接与fsutil reparsepoint query并检查%errorlevel%是否成功，如下所示：

set tmpfile=%TEMP%\%RANDOM%.tmp

fsutil reparsepoint query "%DIR%" >"%tmpfile%"
if %errorlevel% == 0 echo This is a symlink/junction
if %errorlevel% == 1 echo This is a directory

这是有效的，因为fsutil reparsepoint query无法在标准目录上执行任何操作并引发错误。 但是权限错误也会导致%errorlevel%=1 ！

解决方案2：目录+查找

使用dir列出父目录的链接，使用find过滤输出并检查%errorlevel%是否成功，如下所示：

set tmpfile=%TEMP%\%RANDOM%.tmp

dir /AL /B "%PARENT_DIR%" | find "%NAME%" >"%tmpfile%"
if %errorlevel% == 0 echo This is a symlink/junction
if %errorlevel% == 1 echo This is a directory

解决方案 3：为了（最好的）

使用for获取目录的属性并从中检查最后一个，因为这表示链接。 我认为这是更聪明和最好的解决方案。

for %i in ("%DIR%") do set attribs=%~ai
if "%attribs:~-1%" == "l" echo This is a symlink/junction

仅供参考：此解决方案不依赖于%errorlevel% ，因此您也可以检查“有效错误”！

来源

• http://blogs.technet.com/b/filecab/archive/2013/02/14/dfsr-reparse-point-support-or-avoiding-schr-246-dinger-s-file.aspx
• 如何使用批处理文件获取文件的属性

Answer 2

通用代码：

fsutil reparsepoint query "folder name" | find "Symbolic Link" >nul && echo symbolic link found || echo No symbolic link

---

弄清楚，如果当前文件夹是一个符号链接：

fsutil reparsepoint query "." | find "Symbolic Link" >nul && echo symbolic link found || echo No symbolic link

---

弄清楚，如果父文件夹是符号链接：

fsutil reparsepoint query ".." | find "Symbolic Link" >nul && echo symbolic link found || echo No symbolic link

Answer 3

实际上，如果在文件名后附加星号，DIR 可以正常工作，因此：

dir %filename%* |  find "<SYMLINKD>" && (
   do stuff
)

当目录中有另一个与 %filename%* 匹配的条目时，GreenAsJade 提醒我注意此解决方案的失败。 我相信以下内容适用于所有情况：

set MYPATH=D:\testdir1
set FILENAME=mylink
set FULL=%MYPATH%\%FILENAME%
set SP1=0
for /f "tokens=4,5 delims= " %%A IN ('dir /L /N %FULL%*') do (
    if %%B EQU %FILENAME% (
    if "%%A" EQU "<SYMLINKD>" set SP1=1
    )
)
if %sp1% EQU 0 echo It's not there.
if %sp1% EQU 1 echo BINGO!
Pause

Answer 4

这也有效：

dir /al|find /i "java"|find /i "junction" && ( echo 目录是一个符号链接)

Answer 5

更新：这很好地解决了我的任务，但正如评论者指出的那样， dir将显示目录符号链接和目录连接。 所以如果有交叉点，答案是错误的。

---

简单的dir /A:ld工作正常

dir /? ：

DIR [drive:][path][filename] [/A[[:]attributes]] …

/A          Displays files with specified attributes.  
attributes   D  Directories                R  Read-only files  
             H  Hidden files               A  Files ready for archiving  
             S  System files               I  Not content indexed files  
             L  Reparse Points             -  Prefix meaning not  

Answer 6

相应的DIR 命令显示在以下批处理文件(reparse.bat) 中 -

  ::  Specify the Directory to search
  SET directory=C:\Users\%username%\Desktop\TEST1

  ::  Results Text
  echo SEARCH OF DIRECTORY FOR REPARSE POINTS & echo.

  ::  List files with ATTRIBUTE L (Reparse Points)
  DIR "%directory%" /A:L

  echo. && echo  Notes - && echo.
  echo  There are 3 types of Reparse points: && echo.
  echo  ^<JUNCTION^> is a Directory Junction
  echo  ^<SYMLINKD^> is a Directory SymLink
  echo  ^<SYMLINK^>  is a File SymLink
  echo. && echo.

Answer 7

另一种方法是在以下批处理文件(reparse2.bat) 中分别处理三种类型的重解析点中的每一种，可以轻松修改该文件以仅搜索您感兴趣的链接类型 -

  ::  Directory to Search
  SET directory=C:\Users\%username%\Desktop\TEST1

  ::  Results Text
  echo SEARCH OF DIRECTORY: %directory% & echo.

  ::  Find FILE SymLinks in directory
  dir "%directory%" | find "<SYMLINK>" && (
    echo This is a SymLink FILE
  ) && ( echo. )

  ::  Find DIRECTORY SymLinks in directory
  dir "%directory%" | find "<SYMLINKD>" && (
    echo This is a SymLink DIRECTORY
  ) && ( echo. )

  ::  Find JUNCTIONS in directory
  dir "%directory%" | find "<JUNCTION>" && (
    echo This is a Directory JUNCTION
  ) && ( echo. ) && ( echo. )

Answer 8

适用于 Windows 10 的简单示例脚本。

信息：如果它在%localappdata%\\MegaDownloader文件夹中作为SymLink存在，请执行MegaDownloader.exe 。 如果%localappdata%\\MegaDownloader中不存在 SymLink，则使用mklink创建当前文件夹的 SymLink PortableData路径到%localappdata%\\MegaDownloader ，然后运行MegaDownloader.exe 。

fsutil reparsepoint query "%localappdata%\MegaDownloader" | find "Substitute" >nul && GOTO MD || mklink /D /J "%localappdata%\MegaDownloader" "%cd%\PortableData" >nul 2>&1
    
:MD
"%~dp0\MegaDownloader.exe"