创建Win7批处理文件以从所有文件夹中复制文件

Question

我正在尝试编写一个批处理文件来执行以下任务：

1. 我在一个文件夹（ABC）中有20个子文件夹（牛奶，奶酪，蛋白质... ） 。 每个子文件夹在.csv中都有大约15个月度文件，分别命名为2013-10-01、2013-09-02、2013-07-31....。

2. 这些月度文件按月添加，并且没有关于其名称的模式，例如，可能是10月的第一天，但​​11月的第四天。 因此，每个月我都会向每个子文件夹添加一个新文件，即文件数量在增加；

3. 每个月，对于每个子文件夹/类别，我都想将最近的9个每月文件复制到另一个位置，例如CDE文件夹 ；

4. 将它们复制到文件夹CDE之后 ，我将它们全部合并到一个文件中，该文件具有使用当前时间（%% d-%% e-%% f）定义的唯一名称。 这样，我可以每个月获得每个类别的月度文件。

我能够为第4步编写代码，并且想知道你们中的任何人在第3步中是否可以提供帮助。 现在，我必须每次都手动复制并粘贴所有20个子文件夹中的9个文件。 这是非常低效的，我知道一些批处理命令绝对可以使过程更快，更容易。

非常感谢你！

Answer 1

setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir abc /b /o-d') do (set /a a=0&for /f "delims=" %%j in ('dir "abc\%%~i" /b /o-d') do (set /a a+=1&if !a! LEQ 9 (copy /Y "abc\%%~i\%%~j" cde)))

将此放在abc和cde所在的文件夹中
如果这不是您想要的，请详细说明。

Answer 2

编辑修复了“复制所有文件”的问题。

这应该执行以下操作：（更改c：\\ cde和c：\\ abc）

1）从文件夹中复制9个最新文件
2）将它们全部合并到一个名为foldername-HHMMSS的文件中（来自time变量）
3）在c：\\ ABC文件夹中创建foldername-HHMMSS文件
4）删除9个复制的文件
5）对每个文件夹重复

@echo off
set "source=D:\ABC"
set "target=C:\files\CDE"
setlocal enabledelayedexpansion
md "%target%" 2>nul
for /d /r "%source%" %%a in (*) do (
  pushd "%%a"
     set num=0
         for /f "delims=" %%b in ('dir /o-d /b /a-d') do (
           set /a num+=1
           if !num! LSS 10 copy "%%b" "%target%" >nul
         )
     set t=!time!
     set t=!t:~0,2!!t:~3,2!!t:~6,2!
     copy "%target%\*.*" "%source%\%%~nxa-!t!" >nul
     echo "%source%\%%~nxa-!t!" created from "%%a"
     if defined target del "%target%\*.*?"
  popd
)
pause