知道谁是具有更多子节点的元素

Question

我对XML文档进行投票。 我必须知道有更多票数的提议，我该怎么办？ 我正在使用XSLT进行转换，但找不到解决方法。

XML：

<tns:vote>
  <tns:alternative>
    <tns:description>50% do valor recebido das propinas será aplicado em investigação</tns:description>
      <tns:votes>
        <tns:member_vote member_id="i2"/>
        <tns:member_vote member_id="i6"/>
        <tns:member_vote member_id="i7"/>
      </tns:votes>
    <tns:description>20% do valor recebido das propinas será aplicado em investigação</tns:description>
      <tns:votes>
        <tns:member_vote member_id="i4"/>
        <tns:member_vote member_id="i5"/>
      </tns:votes>
  </tns:alternative>        
</tns:vote>

在这个例子中，第一个描述应该是获胜者的提议。

Answer 1

在xslt 1.0中，您可以使用xsl：sort指令，例如：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tns="tns">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="/">
        <result>
            <xsl:apply-templates select="tns:vote/tns:alternative" />
        </result>
    </xsl:template>

    <xsl:template match="tns:alternative">
        <!-- Process all description -->
        <xsl:for-each select="tns:description">
            <!-- Sort them descending by count votes in the first following sibling tns:votes -->
            <xsl:sort select="count(following-sibling::tns:votes[1]/tns:member_vote)" order="descending" />
            <!-- Do anything with that, e.g. make a deep copy -->
            <xsl:copy-of select="." />
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

生成带有描述的xml（按投票顺序降序排列）。

如果只需要一个值（“赢家”），则可以在for-each内部使用例如<xsl:if test="position() = 1">...</xsl:if> 。

Answer 2

该解决方案结合了@Jirka的XSLT 1.0方法和我对多个最佳投票的评论，并仅输出所有最佳投票的列表。 它使用准备步骤来确定最佳投票数，然后在第二步中选择具有最佳投票数的所有投票。 请注意，在第二步中，我们不再需要排序。 如果有必要，我们仍然可以进行排序，如果还有另一个明智的标准可以打破最佳选票的对称性。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet 
    version="1.0"
    xmlns:tns="mynamespace"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
  <xsl:strip-space elements="*"/>

  <xsl:template match="/tns:vote/tns:alternative">

    <!-- compute the best vote count; just the number not the elements -->
    <xsl:variable name="best_vote">
      <xsl:for-each select="tns:description">
        <xsl:sort select="count(following-sibling::tns:votes[1]/tns:member_vote)" order="descending"/>
        <xsl:if test="position() = 1">
          <xsl:value-of select="count(following-sibling::tns:votes[1]/tns:member_vote)"/>
        </xsl:if>
      </xsl:for-each>
    </xsl:variable>

    <tns:result>
      <xsl:for-each select="tns:description"> <!-- we need not sort here anymore! -->

        <!-- only dump those entries which match the best vote count -->
        <xsl:if test="count(following-sibling::tns:votes[1]/tns:member_vote) = number($best_vote)">

          <tns:winning_vote vote_count="{count(following-sibling::tns:votes[1]/tns:member_vote)}">
            <xsl:copy-of select="."/>
            <xsl:copy-of select="following-sibling::tns:votes[1]/tns:member_vote"/>
          </tns:winning_vote>

        </xsl:if>

      </xsl:for-each>
    </tns:result>
  </xsl:template>
</xsl:stylesheet>

Answer 3

在XSLT 2.0中，可以将for-each-group标记与sort一起使用。 以下XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet 
    version="2.0"
    xmlns:tns="mynamespace"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />

  <xsl:template match="/tns:vote/tns:alternative">

    <xsl:for-each-group select="*" group-starting-with="tns:description">
      <xsl:sort select="count(current-group()[2]/tns:member_vote)" order="descending"/>

      <xsl:if test="position() = 1">

        <tns:winning_alternative vote_count="{count(current-group()[2]/tns:member_vote)}>
          <xsl:copy-of select="current-group()"/>
        </tns:winning_alternative>

      </xsl:if>

    </xsl:for-each-group>
  </xsl:template>
</xsl:stylesheet>

产生这个结果

<?xml version="1.0" encoding="UTF-8"?>
  <tns:winning_alternative xmlns:tns="mynamespace" vote_count="3">
   <tns:description>50% do valor recebido das propinas será aplicado em investigação</tns:description>
   <tns:votes>
      <tns:member_vote member_id="i2"/>
      <tns:member_vote member_id="i6"/>
      <tns:member_vote member_id="i7"/>
    </tns:votes>
</tns:winning_alternative>      

请注意，如果一个以上的选择具有相等的最佳投票，XSLT只会选择其中之一。