Excel VBA查找功能会有副作用吗？

Question

所有。 我是VBA和MS EXCEl 2010的新手。昨天我才刚刚开始使用EXCEL中的宏模块，几乎没有体验。

我试图做的描述如下。 首先在sheet1中的某个范围内搜索值记录，然后对于找到的每个单元格，找到该行，并在该行中提取另一个单元格值。 使用此值在sheet2的范围内进行另一次搜索。 我会指出我的代码后遇到的问题。 这是伪代码。

 Dim Found As Range
 With RangeInSheet1
        Set Found = .Find(value1)
        If Not Found Is Nothing Then
            firstAddress = Found.Address
            Do  
                With RangeInSheet2
                    ColumnIndex = .Find(value2).Column
                End With
                Set Found = .FindNext(Found)
            Loop While Not Found Is Nothing And Found.Address <> firstAddress
        End If
End With

value1是我在RangeSheet1中搜索的键，而value2是我在RangeSheet2中搜索的键。 上面的代码遍历了我在工作表1中为value1找到的每条记录，并在工作表Sheet2中进行了另一次搜索。

现在，我们说value1 = 1，value2 = 2007，并且在工作表1中有5条记录包含value1。问题出在此行代码“ ColumnIndex = .Find（value2）.Column”。

假设，对于所有五个找到的记录，执行“ Set Found = .FindNext（Found）”后，Found的值应始终为1。 但是，在我添加了此ColumnIndex代码之后，Found的值设置为2007，这对我来说很奇怪。 有人知道是什么问题吗？ 任何帮助将不胜感激。 我真的需要保持Found行为符合我的期望。

如果不清楚，请告诉我

Answer 1

.Find/.Findnext记住上一个设置。 因此，始终建议完全指定参数。 特别是After:=参数。 它还会记住您最近的搜索词What:=

这是有关如何使用.Find/.Findnext

也不Value2用作变量。 这是保留字。 我在下面的代码中使用sSearch1和sSearch2而不是使用Value1和Value2

假设您的床单看起来像这样

现在尝试此代码

Sub Sample()
    Dim ws1 As Worksheet, ws2 As Worksheet
    Dim rngWs1 As Range, rngWs2 As Range
    Dim aCell As Range, bCell As Range, cCell As Range, dCell As Range, eCell As Range, cl As Range
    Dim sSearch1, sSearch2

    Set ws1 = ThisWorkbook.Sheets("Sheet1")
    Set rngWs1 = ws1.Range("A1:A10")

    Set ws2 = ThisWorkbook.Sheets("Sheet2")
    Set rngWs2 = ws2.Cells

    With ws1
        For i = 1 To 10
            sSearch1 = .Range("A" & i).Value
            Set aCell = .Range("A" & i)

            If Len(Trim(sSearch1)) <> 0 Then
                Set aCell = rngWs1.Find(What:=sSearch1, After:=aCell, LookIn:=xlValues, _
                LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
                MatchCase:=False, SearchFormat:=False)

                If Not aCell Is Nothing Then
                    sSearch2 = aCell.Offset(, 1).Value

                    With ws2
                        Set bCell = rngWs2.Find(What:=sSearch2, After:=.Range("A1"), LookIn:=xlValues, _
                                LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
                                MatchCase:=False, SearchFormat:=False)

                        If Not bCell Is Nothing Then
                            Debug.Print "For " & sSearch1 & ", " & sSearch2 & " Found in " & bCell.Address

                            Set cCell = bCell

                            Do
                                Set bCell = rngWs2.FindNext(After:=bCell)

                                If Not bCell Is Nothing Then
                                    If bCell.Address = cCell.Address Then Exit Do
                                    Debug.Print "For " & sSearch1 & ", " & sSearch2 & " Found in " & bCell.Address
                                Else
                                    Exit Do
                                End If
                            Loop
                        End If
                    End With
                End If
            End If
        Next
    End With
End Sub

这就是我们得到的结果。