在VHDL中从无符号的numeric_std转换为std_logic_vector

Question

我有一个与从numeric_std转换为std_logic_vector的问题。 我正在使用在网上看到的移动平均滤波器代码，并对ADC值进行滤波以稳定这些值。

过滤器程序包代码为：

library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;

package filterpack is
  subtype number is unsigned(27 downto 0);
  type numbers is array(natural range <>) of number;
  function slv_to_num(signal slv: in std_logic_vector) return number;
  procedure MAF_filter(
    signal x: in    number;
    signal h: inout numbers;
    signal y: out   number
  );
end filterpack;

package body filterpack is

function slv_to_num(signal slv: in std_logic_vector) return number is
  variable x: number := (others => '0');
begin
  for i in slv'range loop
    if slv(i) = '1' then
      x(i+4) := '1';
    end if;
  end loop;
  return x;
end function slv_to_num;

procedure MAF_filter(
    signal x: in    number;
    signal h: inout numbers;
    signal y: out   number
  ) is
begin
  h(0) <= x + h(1);       -- h[n] = x[n] + h[n-1]
  y <= h(0) - h(h'high);  -- y[n] = h[n] - h[n-M]
end MAF_filter;

end package body filterpack;

在我的顶级文件中，我调用了MAF_filter过程。

Asign_x: x <= slv_to_num(adc_dat);
Filter:  MAF_filter(x,h,y);

adc_dat定义为：

adc_dat : out std_logic_vector (23 downto 0);

我想将MAF_Filter的输出转换为std_logic_vector（从23降为0）。 谁能告诉我如何将过滤器输出“ y”转换为“ std_logic_vector”？

非常感谢！

Answer 1

您想对这4个额外的位做什么？ 您的类型number有28位，但是信号adc_dat只有24位。

如果可以丢弃它们，则可以使用：

adc_dat <= std_logic_vector(y(adc_dat'range));

另外，是否有理由不编写如下所示的函数slv_to_num ？

function slv_to_num(signal slv: in std_logic_vector) return number is
begin
  return number(slv & "0000");
end function slv_to_num;

Answer 2

转换必须解决两个问题：您注意到的类型差异以及两个单词的大小不同这一事实。

类型差异很容易： std_logic_vector (y)将为您提供正确的类型。 因为这两种类型是相关类型，所以这只是强制转换。

大小差异...只有您有知识可以做到这一点。

adc_dat <= std_logic_vector(y(23 downto 0))将为您提供Y的adc_dat <= std_logic_vector(y(23 downto 0))即Y的值本身，但会溢出。 或如里克所说， adc_dat <= std_logic_vector(y(adc_dat'range)); 通常更好，但是我想公开细节。

adc_dat <= std_logic_vector(y(27 downto 4))不会溢出，但实际上为y / 16。