提供从XSLT中的函数接收的数组的输出

Question

我试图通过XSLT在XML标签中呈现从VBScript函数接收到的数组的输出。 但是文件结构不只是正确的。

这是XSLT代码：

<PID25>
<xsl:variable name='var:vRaceArray' select='userVBScript:readfile(string(DEMOGRAPHICS/DEM_RACE/text()))'/>
<xsl:for-each select="$var:vRaceArray">
<PID25.1>
<xsl:value-of select="."/>
<PID25.1>
</xsl:for-each>
</PID25>  

VBscript代码如下：

Function readfile(p_String1)

Set userArrayList = CreateObject("System.Collections.ArrayList")
StrRace = p_String1
For i = 0 To Len(p_String1)
Do 
    p_String1 = Mid(StrRace, i + 1, 1)
    If p_String1 = 0 Then
    'GoTo Now
    End If

'MsgBox (p_String1)
If Trim(p_String1) = "0" Then
        fctSelectRaceDes = ""
    ElseIf Trim(p_String1) = "1" Then
        fctSelectRaceDes = "American Indian or Alaska Native"
    ElseIf Trim(p_String1) = "2" Then
        fctSelectRaceDes = "Asian"
    ElseIf Trim(p_String1) = "3" Then
        fctSelectRaceDes = "Black or African-American"
    ElseIf Trim(p_String1) = "4" Then
        fctSelectRaceDes = "Native Hawaiian or Other Pacific Islander"
    ElseIf Trim(p_String1) = "5" Then
        fctSelectRaceDes = "White"
    ElseIf Trim(p_String1) = "6" Then
        fctSelectRaceDes = ""
    ElseIf Trim(p_String1) = "7" Then
        fctSelectRaceDes = "Native Hawaiian or Other Pacific Islander"
    ElseIf Trim(p_String1) = "8" Then
        fctSelectRaceDes = "Other Race"
End If
'MsgBox (fctSelectRaceDesc)
'ArrayRace(i) = fctSelectRaceDesc
'MsgBox (ArrayRace(i))
userArrayList.Add fctSelectRaceDes

Loop While False
i = i + 1
Next



Set readfile = userArrayList
End Function

任何人都可以为此提供解决方案吗？

Answer 1

这是使用普通XSLT 1.0的方法：

<xsl:stylesheet version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:data="http://example.com/data"
  exclude-result-prefixes="data">

<xsl:param name="wrap-name" select="'PID25.1'"/>

<data:data xmlns="">
  <code number="1">American Indian or Alaska Native</code>
  <code number="2">Asian</code>
  <code number="3">Black or African-American</code>
  <code number="4">Native Hawaiian or Other Pacific Islander</code>
  <code number="5">White</code>
  <code number="6"></code>
  <code number="7">Native Hawaiian or Other Pacific Islander</code>
  <code number="8">Other Race</code>
</data:data>

<xsl:output indent="yes"/>

<xsl:key name="race" match="code" use="@number"/>

<xsl:variable name="stylesheet" select="document('')"/>

<xsl:template name="map">
  <xsl:param name="code"/>
  <xsl:param name="wrap" select="$wrap-name"/>
  <xsl:if test="$code != '0'">
    <xsl:for-each select="$stylesheet">
      <xsl:element name="{$wrap}">
        <xsl:value-of select="key('race', $code)"/>
      </xsl:element>
    </xsl:for-each>
  </xsl:if>
</xsl:template>

<xsl:template name="wrap-tokens">
  <xsl:param name="string"/>
  <xsl:param name="sep" select="','"/>
  <xsl:param name="name" select="$wrap-name"/>
  <xsl:choose>
    <xsl:when test="not(contains($string, $sep))">
      <xsl:call-template name="map">
        <xsl:with-param name="code" select="$string"/>
        <xsl:with-param name="wrap" select="$name"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="map">
        <xsl:with-param name="code" select="substring-before($string, $sep)"/>
        <xsl:with-param name="wrap" select="$name"/>
      </xsl:call-template>
      <xsl:call-template name="wrap-tokens">
        <xsl:with-param name="string" select="substring-after($string, $sep)"/>
        <xsl:with-param name="sep" select="$sep"/>
        <xsl:with-param name="name" select="$name"/>
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="DEM_RACE">
  <xsl:call-template name="wrap-tokens">
    <xsl:with-param name="string" select="."/>
  </xsl:call-template>
</xsl:template>

</xsl:stylesheet>

将<DEM_RACE>0,1,2,5,6,8</DEM_RACE>转换为

<PID25.1>American Indian or Alaska Native</PID25.1>
<PID25.1>Asian</PID25.1>
<PID25.1>White</PID25.1>
<PID25.1/>
<PID25.1>Other Race</PID25.1>