Oracle隐式游标：for-else

Question

这是一个非常基本的问题，但是在Oracle PL / SQL FORELSE写入隐式游标的最佳方法是什么？ 一些编程语言允许这种语法，当游标不返回任何行时执行FORELSE块。

我想要实现的是以下几行内容（伪代码）：

DECLARE
    CURSOR test_cur IS
        SELECT 'a'
        FROM   table_with_zero_or_more_data;
BEGIN
    FOR r_ IN test_cur LOOP
        Dbms_Output.Put_Line ('One extra row found');
    FORELSE
        Dbms_Output.Put_Line ('No data found');
    END LOOP;
END;

我已经尝试过如下使用异常，但是NO_DATA_FOUND异常不会被隐式游标触发。

DECLARE 
    CURSOR test_cur IS
        SELECT 'a'
        FROM   table_with_zero_or_more_data;
BEGIN
    BEGIN
        FOR r_ IN test_cur LOOP
            Dbms_Output.Put_Line ('One extra row found');
        END LOOP;
    EXCEPTION
        WHEN NO_DATA_FOUND THEN
            Dbms_Output.Put_Line ('No data found');
    END;
END;

以下内容当然可以工作（毫无疑问，这里有类似的变化）。 但我只是觉得这种方式有些笨拙。 当代码变得更加真实和冗长时，将IF语句链接到FOR循环并不是那么明显/直观。 它还会强制引入虚拟变量，而且语法上并不美观。

DECLARE 
    CURSOR test_cur IS
        SELECT 'a'
        FROM   table_with_zero_or_more_data;
    i NUMBER := 0;
BEGIN
    FOR r_ IN test_cur LOOP
        i := i + 1;
        Dbms_Output.Put_Line ('One extra row found');
    END LOOP;
    IF i = 0 THEN
        Dbms_Output.Put_Line ('No data found');
    END IF;
END;

我只是想知道是否有更好的方法，它更直观，并整合了FOR和IF条件？

编辑

如果我不够清楚，那么重点是在IMPLICIT游标中执行此操作。 我知道我可以使用EXplicit游标并检查%NOTFOUND等（实际上%ROWCOUNT更好）。

Answer 1

据我所知，因为PL / SQL缺少forelse构建并没有办法推出自己的结构，你可以希望的是使用一个额外的状态变量，以迎合隐式游标的情况下，最好for -loop处理任何行。

但是，您可以通过这样的方式来构造代码，以便更清楚地了解正在发生的事情：

declare
  cursor test_c is
    with data_ as (
      select 1 as id, 'foo' as str from dual union all
      select 2 as id, 'bar' as str from dual
    )
    select str from data_ where id > 2;

  -- isolate the data processing into a dedicated subroutine/package
  -- pass all required information as parameters
  procedure process_data(p_data in test_c%rowtype) is
  begin
    dbms_output.put_line('processing: ' || p_data.str);
  end;
begin
  -- more things can take place here ...

  -- isolate the data processing into a dedicated block or subroutine
  -- with a block level comment like: processing all foos and bars to
  -- conform business rule car. (or even better: name the subroutine 
  -- accordingly !)
  declare
    v_has_data boolean := false;
  begin
    for d in test_c loop
      v_has_data := true;
      process_data(d);
    end loop;

    if not v_has_data then
      dbms_output.put_line('no data processed');
    end if;
  end;

  -- more things can take place here ...
end;
/

即使我非常同意这种方法的错误…… 笨拙 ，请记住所有编程语言都需要权衡取舍。

Answer 2

尝试使用一个简单的循环并使用游标的%NOTFOUND属性进行测试，如下所示：

DECLARE 
    CURSOR test_cur IS
        SELECT 'a'
        FROM   table_with_zero_or_more_data;
    r_test test_cur%ROWTYPE;
BEGIN
    OPEN test_cur;

    FETCH test_cur INTO r_test;

    IF test_cur%NOTFOUND THEN
        dbms_output.put_line('No data found');
    ELSE
        LOOP
            FETCH test_cur INTO r_test;
            EXIT WHEN test_cur%NOTFOUND;
            dbms_output.put_line('One extra row found');
            -- 
            -- other routine code if there are rows found.
            -- 
        END LOOP;
    END IF;
END;
/

有关FETCH更多详细信息，请参见Oracle Docs 。

另请在下面的评论中查看Nicholas Krasnov撰写的SQL Fiddle。 这是非常有帮助的。

Answer 3

一种类似的方法是使用游标的％ROWCOUNT属性。 有关其他游标属性的引用，请使用链接http://docs.oracle.com/cd/B12037_01/appdev.101/b10807/13_elems011.htm下面提供了使用ROWCOUNT的实现。

DECLARE 
CURSOR test_cur IS
    SELECT 'a'
    FROM   table_with_zero_or_more_data;
i NUMBER := 0;
r_test test_cur%ROWTYPE;
BEGIN
   OPEN test_cur;

LOOP
    FETCH test_cur INTO r_test;
    IF NOT test_cur%ROWCOUNT > 0 THEN
        dbms_output.put_line("No data found");
        EXIT;
    ELSE
        dbms_output.put_line("extra row found. Row count is now "||test_cur%ROWCOUNT);
    END IF;
    ...
    ... -- other routine code if there are rows found.
    ...
END LOOP;
END;
/

Answer 4

 DECLARE
     CURSOR CEMP 
     IS 
     SELECT *FROM EMP ;
     V_EMP CEMP%ROWTYPE;
 BEGIN
     OPEN CEMP;
     LOOP
         FETCH CEMP INTO V_EMP;
         IF CEMP%ROWCOUNT=0 or  CEMP%ROWCOUNT IS NULL  
         THEN
             DBMS_OUTPUT.PUT_LINE('No Data Found');
         END IF;
         EXIT WHEN CEMP%NOTFOUND;
         DBMS_OUTPUT.PUT_LINE(V_EMP.ENAME);
     END LOOP;
     CLOSE CEMP;
 END;
/