Windows批处理文件中的正则表达式

Question

我正在寻找一种通过批处理作业重命名多个文件的方法。 是的，我知道有许多应用程序可以实现此目的。 但是我需要一种自动化的方式，例如可以从调度程序（SOS Job Scheduler）调用的批处理文件之类的东西。 我们每天需要重命名数百个文件！

目标是在文件开头设置17-25个字符。

• 00010028229720270014468393_TB-E.pdf-> 00144683930001002822972027_TB-E.pdf
• 000100282297202700144683931ESR-AF.pdf-> 001446839300010028229720271ESR-AF.pdf
• 00010031141040250016353371ESR-AF.pdf-> 00163533700010031141040251ESR-AF.pdf
• 0001003167580004001667217KTO.pdf-> 0016672170001003167580004KTO.pdf

这是一个更清晰的示例：

0001 002822972 027 001446839 _TB-E .pdf-> 001446839 0001 002822972 027 _TB-E .pdf

Answer 1

@ECHO OFF
SETLOCAL
SET "sourcedir=c:\sourcedir"
FOR /f "delims=" %%a IN (
 'dir /b /a-d "%sourcedir%\*" '
 ) DO (
 SET "name=%%a"
 CALL :transform
)

GOTO :EOF

:transform
ECHO REN "%sourcedir%\%name%" "%name:~16,9%%name:~0,16%%name:~25%"
GOTO :eof

所需REN命令仅仅ECHO编用于测试目的。 验证命令正确后，将ECHO REN更改为REN即可真正重命名文件。

请注意，您介绍的第一个示例在转换后的版本中具有... 39 3 _TB-E ...，但缺少3 。

Answer 2

借助REPL.BAT可以非常简单地完成此操作-REPL.BAT是一个混合的JScript / batch实用程序，它执行正则表达式搜索并替换stdin的每一行并将结果写入stdout 。 该实用程序仅使用本机脚本功能，从XP以后的任何现代Windows机器都可以使用； 无需第三方可执行文件。 完整的文档嵌入在脚本中。

假设REPL.BAT在您的PATH中：

@echo off
pushd "c:\sourcePath"
for /f "delims=" %%A in (
  'dir /b /a-d *.pdf ^| repl "(.{16})(.{9}).*" "ren \q$&\q \q$2$1*\q" x'
) do %%A
popd

仅使用本机批处理命令，不使用任何CALL：

@echo off
setlocal disableDelayedExpansion
pushd "c:\sourcePath"
for /f "delims=" %%F in ('dir /b /a-d *.pdf') do (
  set "file=%%F"
  setlocal enableDelayedExpansion
  ren "!file!" "!file:~16,9!!file:~0,17!*"
  endlocal
)
popd

如果您知道您的文件名都不包含! 字符，那么您只需在顶部启用延迟扩展，然后从循环内删除SETLOCAL和ENDLOCAL。

以上两种解决方案都基于以下事实：目标名称末尾的*将保留原始文件名的其余部分。 请参阅Windows RENAME命令如何解释通配符？ 有关更多信息。

Answer 3

(\d{16})(\d+)(.*?\.pdf)  ->  \2\1\3

{16}表示您重复了16次（一个数字）