在Flash Pro中对实例进行动画处理

Question

因此，我有一个包含3个框架，一个开始，规则和实际游戏框架的游戏。

我想要一张从中性表情变成皱着眉头的脸，同时不断向下移动的图像。 我知道将其移下即可

instancename.y += 10;

但是当它下降时，我如何才能使它不时皱眉呢？

我已经绘制了表达式的多个面，那么我需要皱眉吗？

我有photoshop，如果有很大的不同，

Answer 1

所以我不确定你想要皱眉的频率。 可以是随机时间，也可以是一定距离后，也可以使用Timer将其设置为以指定的间隔运行。 因此，我将解释所有3。

首先是随机时间。 您需要为此解决方案导入import flash.utils.getTimer 。 我假设您要让皱着眉头的脸保持皱着眉头超过1毫秒。 如果是这种情况，那么我会这样做：

设置此成员变量：

private var beginTime:Number;

然后，在运行第一个移动功能之前：

beginTime = getTimer();

在循环或运动函数中包含instancename.y + = 10;

private function loop():void {
    instancename.y += 10;

    //get our delta time        
    var dt:Number = getTimer() - beginTime; 
    //set random variable 50% chance to change the frame    
    var random:int = Math.random() * 2;

    //dt > 3000 just means 3 seconds have passed, you can lower that number to decrease the delay before we change frames for the "face" animation
    if ( random > 0 && dt > 3000 ) {
        beginTime = getTimer();

        if ( instancename.currentFrameLabel == "neutral" ) {
            instancename.gotoAndPlay("frowning");
        } 
        else {
            instancename.gotoAndStop("neutral");
        }
    }
}

这将在随机时间更改帧，延迟3000毫秒或3秒（可以随意更改）。

现在是远程版本。 因此，这基本上只是说，当我们距某个原点一定距离时，请更改框架。 但是这取决于设置的几个变量：

//set the variable origin and a maxDistance
private var origin:Point = new Point( instancename.x, instancename.y );
private var maxDistance:int = 50;

//then in your loop or movement function
private function loop():void {
    instancename.y += 10;

    //when our distance is >= to our maxDistance, change the frame
    if ( Point.distance( new Point( spr.x, spr.y ), origin ) >= maxDistance ) {
        if ( instancename.currentFrameLabel == "neutral" ) {
            instancename.gotoAndPlay("frowning");
        } 
        else {
            instancename.gotoAndStop("neutral");
        }
        //set the origin variable again
        origin = new Point( instancename.x, instancename.y );
    }

最后是计时器功能。 使用TimerEvent.TIMER事件侦听器和要调用的函数来设置计时器变量：

private var timer:Timer = new Timer(3000, 0);

然后在适用的地方进行设置：

timer.addEventListener(TimerEvent.TIMER, changeFrame);
timer.start(); //to start your timer

然后在计时器功能中：

private function changeFrame( e:TimerEvent ):void {
    if ( instancename.currentFrameLabel == "neutral" ) {
        instancename.gotoAndPlay("frowning");
    } 
    else {
        instancename.gotoAndStop("neutral");
    }
}

使用timer.stop()它后，别忘了停止它： timer.stop() ;

这些是解决该问题的几种方法。 我应该注意，第二种解决方案（距离一个）可以通过多种不同方式进行优化，这只是其中一种方式。

希望这有帮助，祝你好运！