四舍五入有效数字规则

Question

有什么方法可以将有效数字规则应用于Excel工作表，即从宏打印值？

还是以任何方式通过VBA宏计算出的值都通过有效数字规则，然后打印在excel表上？

Answer 1

这是有效数字的公式：

=ROUND(REFERENCE,SIGFIGS-1-INT(LOG10(ABS(REFERENCE))))

例如，如果您希望A1中的值为3个有效数字，则可以输入：

=ROUND(A1,2-INT(LOG10(ABS(A1))))

编辑：我只是把一个快速的VBA宏放在一起，如果需要，可以对选择中的每个单元格进行处理：

Sub ConvertToSigfigs()
    Dim Sigfigs As Integer
    Sigfigs = 3 'Change this to whatever value you want
    Dim cel As Range
    For Each cel In Selection
        cel.Value = Application.WorksheetFunction.Round(cel.Value, Sigfigs - 1 - Int(Application.WorksheetFunction.Log10(Abs(cel.Value))))
    Next
End Sub

注意我使用了Application.WorksheetFunction.Round（）而不是VBA的Round（），因此它将与非十进制数一起使用。

编辑2：这是UDF：

Function Sigfig(Inpt As Double, Precision As Integer) As Double
    Sigfig = Application.WorksheetFunction.Round(Inpt, Precision - 1 - Int(Application.WorksheetFunction.Log10(Abs(Inpt))))
End Function

编辑3：这不会做的一件事是保持终端零，例如，如果您有4.0001并四舍五入到三个信号图，excel将显示4，而不是4.00。 如果绝对必要，则可以在基于模的sub中添加格式。

一个精巧的项目是使用UDF，然后有一个子项目，该子项目随后将解析UDF，将其转换为Excel公式，这样您就不必另存为.xlam。

Answer 2

我一直在研究VBA用户定义的函数，以便使用有效数字或有限的小数位数进行科学舍入，这就是我在宏中使用的总和。

要在像'= SciRound（B3,3）'这样的工作表上使用，请按Alt + F11打开Visual Basic编辑器，然后从“插入”菜单中添加一个模块。 将代码复制/粘贴到Module1中，然后使用类似'= SciRound（数字或单元格位置四舍五入，SigFigs，小数位）'

Public Function SciRound(number, sigfigs, Optional decimals As Variant)
'      Nov2013 TP
Dim exp As Integer, n As Integer
Dim bdec As Boolean, test As Variant

If (IsEmpty(number) Or IsMissing(number)) = True Then SciRound = CVErr(xlErrNull)
If IsNumeric(number) = False Then SciRound = CVErr(xlErrValue)

If (IsNumeric(sigfigs) = False) Or (sigfigs < 1) Then SciRound = CVErr(xlErrValue)

If (IsMissing(decimals) Or IsEmpty(decimals)) = True Then bdec = False Else bdec = True
If bdec = True Then
  If (IsNumeric(decimals) = False) Then SciRound = CVErr(xlErrValue)    
  If (Int(decimals) <> decimals) Then SciRound = CVErr(xlErrNum)
End If

If IsError(SciRound) = True Then Exit Function
If number = 0 Then SciRound = 0: Exit Function

number = CDec(number): test = Abs(number): n = 0
n = Int((Log(test) / Log(10#)))  '  natural log to log10
exp = (sigfigs - n) - 1

If bdec = True Then
 If (exp < decimals) Then bdec = False
End If
If bdec = True Then
 SciRound = Round((number * 10 ^ decimals), 0) * 10 ^ -decimals
Else
 SciRound = Round((number * 10 ^ exp), 0) * 10 ^ -exp
End If
End Function