批处理文件以列出带有父目录的文件和文件夹

Question

我见过来自不同人士的脚本，这些脚本建议了下面指出的代码：

    @echo off
    setlocal disableDelayedExpansion
    pushd %1
    set "tab=   "
    set "indent="
    call :listFolder >report.txt
    exit /b

    :listFolder
    setlocal
    set "indent=%indent%%tab%"

    for /d %%F in (*) do (
      echo %indent%%%F
      pushd "%%F"
      call :listFolder
      popd
    )
    for %%F in (*) do echo %indent%%%F

exit /b

输出：

Folder 1
   Subfolder 1
      Filename 1
   Subfolder 2
      Filename 1
Folder 2
   Subfolder 1
      Filename 2
      Filename 2

这在一段时间内效果很好，但我想知道是否有办法执行相同的想法，但是将父文件夹用制表符分隔。

Folder 1
Folder 1    Subfolder 1
Folder 1    Subfolder 1     Filename 1
Folder 1    Subfolder 2
Folder 1    Subfolder 2     Filename 1
Folder 2
Folder 2    Subfolder 1
Folder 2    Subfolder 1     Filename 2
Folder 2    Subfolder 1     Filename 2

Answer 1

@echo OFF
SETLOCAL
pushd %1
set "tab=/"
SET "currdir=%cd%"
call :listFolder >report.txt
popd
GOTO :eof

:listFolder
setlocal
for /d %%a in (*) do (
 SET "name=%%~fa"
 SETLOCAL ENABLEDELAYEDEXPANSION
 SET name=!name:%currdir%=!
 SET name=!name:\=%tab%!
 ECHO !name!
 ENDLOCAL
 pushd "%%a"
 call :listFolder
 popd
)
for %%a in (*) do (
 SET "name=%%~fa"
 SETLOCAL ENABLEDELAYEDEXPANSION
 SET name=!name:%currdir%=!
 SET name=!name:\=%tab%!
 ECHO !name!
 ENDLOCAL
)

GOTO :eof

有趣的运动。

从本质上讲，该报告将变为“执行dir/s/b列表，但用Tab替换\\并省略当前目录”-但是该简单方案不会产生相同的顺序...

（我还用/替换了tab，以使其更易于查看，tab并不是特别明显）-只需选择一个适合的字符即可。

Answer 2

另一个版本：

@echo off
setlocal disableDelayedExpansion
set "pwd=%~1"
if "%pwd%"=="" set "pwd=%cd%"

pushd "%pwd%"
set "indent=   "
call :listFolder1 "%pwd%"
exit /b

:listFolder1 %1
setlocal
set curdir=%~1
for /d %%F in (*) do (
    echo %curdir%%indent%%%F
    for %%S in (*) do echo %curdir%%indent%%%F%indent%%%S
    pushd %%F
    call :listFolder1 "%curdir%%indent%%%F"
    popd
)