AWK：确保输出块后仅一个空白行

Question

以下awk代码输出所需的内容，不同之处在于它在每个数据块之后输出两个空白行。 只需要插入一个空白行。 （没有最后一个{“ print” \\ n“}语句，将不输出任何空行。使用该语句，将有两个空行。我只需要一个空行。）

/Reco/ {for(i=0; i<=2; i++) {getline; print} {print "\n"}}

Answer 1

根据下面的评论，您实际上希望the line that matches /Reco/ and 2 subsequent lines and a blank line (to be inserted after that) ，这是基于以下成语“ g”的操作方法：

awk '/Reco/{c=3} c&&c--{print; if(!c)print ""}' file

有个解释-请记住，awk为您提供了以下功能：

WHILE read line from file
DO
    execute the users script (/Reco/{c=3} c&&c--{print; if(!c)print ""})
DONE

并且awk脚本的主体由以下组成：

<condition> { <action> }

默认条件为TRUE且默认操作为打印当前记录/行的语句。

上面发布的awk脚本执行以下操作：

/Reco/ {         # IF the pattern "Reco" is present on the current line THEN
    c=3          #     Set the count of the number of lines to print to 3
}                # ENDIF
c&&c-- {         # IF c is non-zero THEN decrement c and THEN
    print;       #     print the current line
    if(!c)       #     IF c is now zero (i.e. this is the 3rd line) THEN
        print "" #         print a blank line
                 #     ENDIF
}                # ENDIF

因此，解析输入文件的整个过程为：

WHILE read line from file
DO
    /Reco/ {         # IF the pattern "Reco" is present on the current line THEN
        c=3          #     Set the count of the number of lines to print to 3
    }                # ENDIF
    c&&c-- {         # IF c is non-zero THEN decrement c and THEN
        print;       #     print the current line
        if(!c)       #     IF c is now zero (i.e. this is the 3rd line) THEN
            print "" #         print a blank line
                     #     ENDIF
    }                # ENDIF
DONE

如果脚本是这样写的，也许会更清晰一些：

awk '/Reco/{c=3} c{c--; print; if(c == 0)print ""}' file

---

您已找到所需的答案，但是以下是在awk中执行某些模式后如何真正打印N行的方法：

c&&c--;/pattern/{c=N}

您的情况将是：

c&&c--;/Reco/{c=3}

如果您想添加额外的换行符，则它将变为：

c&&c--{print; if(!c)print ""} /Reco/{c=3}

如果您正在考虑使用getline确保先阅读http://awk.info/?tip/getline并了解所有注意事项，以便您了解自己所要学习的内容。

PS以下成语描述了如何选择给定特定模式以匹配的记录范围：

a）从某种模式打印所有记录：

awk '/pattern/{f=1}f' file

b）按某种模式打印所有记录：

awk 'f;/pattern/{f=1}' file

c）在某些模式后打印第N条记录：

awk 'c&&!--c;/pattern/{c=N}' file

d）按某种模式打印除第N条记录以外的所有记录：

awk 'c&&!--c{next}/pattern/{c=N}1' file

e）按照某种模式打印N条记录：

awk 'c&&c--;/pattern/{c=N}' file

f）按照某种模式打印除N条记录以外的所有记录：

awk 'c&&c--{next}/pattern/{c=N}1' file

g）从某种模式打印N条记录：

awk '/pattern/{c=N}c&&c--' file

我在适当的地方将变量名称从“找到”的“ f”更改为“计数”的“ c”，因为这更能表达变量的实际含义。

Answer 2

@Kevin的帖子提供了具体的答案（使用print ""或@bMW建议的printf ORS ），但这是一些背景知识 ：

在awk ，

print

是相同的：

print $0

即，它打印当前输入行， 后跟输出记录分隔符 -默认为\\n并存储在特殊ORS变量中。

您可以传递参数print来打印$0以外的内容（或除$0之外），但记录分隔符总是附加的。

请注意，如果你通过与分隔的多个参数 ,来print ，他们将是一个输出域分隔的输出-默认为一个空间，并存储在特殊变量OFS 。

相比之下，-更灵活的printf函数采用格式字符串 （如在其C语言版本中一样）和实例化格式字符串中占位符（字段）所需的尽可能多的参数。 输出记录分隔符不会附加到结果中。

例如，等同于不带参数的print的printf等效于：

printf "%s\n", $0  # assumes that \n is the output record separator

或更笼统地说：

printf "%s%s", $0, ORS

请注意，顾名思义， 输出字段/记录分隔符（ OFS / ORS ）具有输入副本（ FS / RS ）-它们各自的默认值是相同的（单个空格/ \\n尽管在解析输入时会处理多个相邻空格）作为单个字段分隔符）。

Answer 3

print已经包括换行符。 只需使用print "" 。