在Chrome中下载简单的文本/ CSV文件失败

Question

我正在尝试找出下载面临的问题，该问题似乎仅在Chrome中存在，并且仅在txt和csv文件中存在。 下载zip文件符合预期。 IE和Firefox适用于所有情况。 由于某些原因，Chrome会在未正确设置名称的情况下下载txt和csv文件。 文件会继承从中下载文件的页面名称，并且没有扩展名（ ）。

我有一个简单的Webform，其中只有3个linkbutton，后面有一个相当简单的代码，为解决这个问题，我对其进行了简化。

Imports System.IO

Public Class _Default
    Inherits Page

    Private Const FILE_PATH_CSV As String = "D:\Temp\Download\testFile.csv"
    Private Const FILE_PATH_ZIP As String = "D:\Temp\Download\testFile.zip"
    Private Const FILE_PATH_TXT As String = "D:\Temp\Download\testFile.txt"

    Private Sub btnDownloadCSV_Click(sender As Object, e As EventArgs) Handles btnDownloadCSV.Click
        Dim file As New FileInfo(FILE_PATH_CSV)
        If Not file.Exists() Then
            Throw New Exception("No file")
        End If
        Try
            DownloadFile(file)
        Catch ex As Exception
            'TODO: Log!
        End Try
    End Sub

    Private Sub btnDownloadTXT_Click(sender As Object, e As EventArgs) Handles btnDownloadTXT.Click
        Dim file As New FileInfo(FILE_PATH_TXT)
        If Not file.Exists() Then
            Throw New Exception("No file")
        End If
        Try
            DownloadFile(file)
        Catch ex As Exception
            'TODO: Log!
        End Try
    End Sub

    Private Sub btnDownloadZIP_Click(sender As Object, e As EventArgs) Handles btnDownloadZIP.Click
        Dim file As New FileInfo(FILE_PATH_ZIP)
        If Not file.Exists() Then
            Throw New Exception("No file")
        End If
        Try
            DownloadFile(file)
        Catch ex As Exception
            'TODO: Log!
        Finally
            With Response
                .Flush()
                .End()
            End With
        End Try
    End Sub

    Private Sub DownloadFile(ByVal file As FileInfo)
        With Response
            .Clear()
            .ClearHeaders()
            .ClearContent()
            .Buffer = True

            Response.ContentType = GetContentType(file)
            Response.AddHeader("Content-Disposition:", String.Format("attachment;filename=""{0}""", file.Name.ToString()))
            Response.AddHeader("Content-Length", file.Length.ToString())
            Response.TransmitFile(file.FullName)
        End With
    End Sub

    Private Function GetContentType(ByVal file As FileInfo)
        Select Case file.Extension.ToLower()
            Case ".txt", ".csv"
                Return "application/octet-stream"
            Case ".zip"
                Return "application/x-zip-compressed"
            Case Else
                Return "application/octet-stream"
        End Select
    End Function
End Class

我尝试在网络上搜索答案时将内容类型切换为“文本/纯文本”或其他选项，但没有运气。 我觉得自己缺少了一些东西，但是找不到任何可以在线回答我问题的东西。 有谁知道为什么会发生这种情况？

任何帮助表示赞赏。

Answer 1

您需要将MIME类型更改为正确的值 。

        Case ".csv"
            Return "text/csv"
        Case ".txt"
            Return "text/plain"

您可能还需要更改从以下位置发送文件的方法

        Response.TransmitFile(file.FullName)

至

        Response.WriteFile(file.FullName, False)

MSDN上的文档尚不清楚这两种方法之间的区别。 我从未使用过TransmitFile ，但已成功使用WriteFile 。

Answer 2

问题解决了。 我猜我应该更加小心复制/粘贴，因为这导致我两天的调试非常沮丧。

Response.AddHeader("Content-Disposition:", String.Format("attachment;filename=""{0}""", file.Name.ToString()))

应该

Response.AddHeader("Content-Disposition", String.Format("attachment;filename=""{0}""", file.Name.ToString()))

里面没有多余的冒号，当我删除它时-一切正常！ 感谢所有的帮助！