VBA：如何将表单作为参数传递

Question

我有一个简单的用户表单，上面有一个按钮。 我想将此表单传递给另一个模块中的函数 - 但即使在同一个模块中，它也无法按预期工作：

Private Sub Test(ByRef oForm As MSForms.UserForm)
    Debug.Print "caption: >" & oForm.Caption & "<"
End Sub

Private Sub CommandButton3_Click()
    Debug.Print "caption: >" & Me.Caption & "<"
    Test Me
    Debug.Print "caption: >" & Me.Caption & "<"
End Sub

当我单击按钮时，它会将其打印到调试控制台：

caption: >UserForm1<
caption: ><
caption: >UserForm1<

所以在Test()子里面， Caption是空白的。

任何想法为什么这不起作用？

注意：如果我使用Variant作为参数类型，它会起作用

Answer 1

类型UserForm并不直接等同于特定用户窗体的实例，而是呈现略有不同的界面。

将表单as Object传递：

Private Sub Test(Form As Object)

或者对于类型安全的方法，用户窗体可以实现接口：

Private Sub Test(Form As IMyForm)

Answer 2

您必须传递用户窗体类型的变量。 这意味着如果您的表单名称是MyForm那么签名应该是

Private Sub Test(ByRef oForm As MyForm)

Answer 3

对我有用的是以下...

1）在主模块中定义一个全局参数如下：

Public gMyForm As MSForms.UserForm

2) 在 UserForm_Initialize() 子中：

Set gMyForm = Me

3）调用函数：

Dim l_dummy as Variant
l_dummy = myFunction(gMyForm)

4）函数签名加上几行随机代码：

Function myFunction(ByRef p_form As MSForms.UserForm) 

Dim l_my_value type string
l_my_value = p_form.myControl.Value  

唯一的奇怪之处，无疑有人可以解释，是需要指定 l_dummy 返回参数，否则你会得到类型不匹配错误。 否则像魅力一样工作..

希望这可以帮助某人。

Answer 4

“唯一的奇怪之处，无疑有人可以解释，是需要指定 l_dummy 返回参数，否则你会得到类型不匹配错误。否则像魅力一样工作......希望这对某人有所帮助。”

这些是语言语法的特征。 您使用该函数，但不指定返回值的类型。 如果您不需要返回任何内容，则使用 Sub()。 如果函数返回某些内容，则必须指定括号：

variant ret = myFunction(gMyForm)

如果它没有返回：

myFunction gMyForm

避免创建不必要的变量：不返回： myFunction Me return： ... = myFunction(Me)签名方法/函数：

Sub myFunction(p_form As MyForm)
........
End Sub

或者

Function myFunction(p_form As MyForm) As Variant
............
   myFunction = p_form.myControl.Value
End Function

Answer 5

下面是我找到的解决方案。 重要的部分是：

1. 在呼叫站点进入Sub ，如果参数在括号内，则需要Call 。 当我省略Call并保留参数周围的括号时，我收到了Run-time error '438': Object doesn't support this property or method 。 当在错误对话框中选择“调试”时，我进入了 VBA 编辑器，它表明Sub本身中的.Visible引用是未找到的。 删除参数周围的括号后，错误就会消失。
2. 在Sub ，接受表单pv_objFrmTarget的参数必须定义为ByVal 。 它不能明确定义为ByRef或未定义（默认为ByRef ）。 当我使用ByRef或忽略它时，我收到了Run-time error '13': Type Mismatch 。 当在错误对话框中选择“调试”时，我进入了 VBA 编辑器，它表明Call s_...语句出错（因为它试图在调用完成后更新ByRef值）。
3. 在Sub ，接受表单pv_objFrmTarget的参数类型必须定义为As Object或As Variant或根本不定义（我认为这会导致默认为As Variant ）。 将其定义为 'UserForm' 会导致Run-time error '438': Object doesn't support this property or method 。 当在错误对话框中选择“调试”时，我进入了 VBA 编辑器，它表明Sub本身中的.Visible引用是未找到的。

---

解决方案1：

呼叫站点代码：

Sub btnClear_Click()
  Call s_FrmShowCenteredOnlyIfHidden(frmClear)
End Sub

Sub站点代码：

Public Sub s_FrmShowCenteredOnlyIfHidden(ByVal pv_objFrmTarget As Object)
  With pv_objFrmTarget
    If (.Visible = False) Then
      .StartUpPosition = 0
      .Left = Application.Left + (0.5 * Application.Width) - (0.5 * .Width)
      .Top = Application.Top + (0.5 * Application.Height) - (0.5 * .Height)
      .Show
    End If
  End With
End Sub

---

解决方案 2：[所有默认值]

呼叫站点代码：

Sub btnClear_Click()
  s_FrmShowCenteredOnlyIfHidden frmClear
End Sub

Sub站点代码：

Public Sub s_FrmShowCenteredOnlyIfHidden(ByVal pv_objFrmTarget)
  With pv_objFrmTarget
    If (.Visible = False) Then
      .StartUpPosition = 0
      .Left = Application.Left + (0.5 * Application.Width) - (0.5 * .Width)
      .Top = Application.Top + (0.5 * Application.Height) - (0.5 * .Height)
      .Show
    End If
  End With
End Sub

Answer 6

将用户表单作为Object传递，如下所示：

..
Call Subroutine(Me)
..

Sub Subroutine(Dialog As Object)
    Dim UF As Object
    Set UF = Dialog
    Debug.Print Dialog.caption, UF.caption
End Sub