帐户触发器更新所有联系人-SOQL查询过多：101

Question

我有一个触发器，该触发器在更新任何帐户后运行，实际上它只是在少数条件后更新所有相关联系人中的字段（Relationship_category_r__c）。

条件1：如果我们将帐户类型更新为“成员”条件2：如果该联系人在（Relationship_category_r__c）字段中还没有“成员”操作：将联系人Relationship_Category_r__c字段更新为“成员-人员”

Condition2：如果我们将帐户类型更新为“会员-过去”操作：将所有联系人的“ Relationship_Category_r__c”字段更新为“会员-过去”

当帐户的联系人少于25到50时，可以完全找到触发器，但是当帐户的联系人超过55个时，触发器会产生错误

错误：Apex触发器UpdateAllContacts导致意外的异常，请与管理员联系：UpdateAllContacts：System.LimitException：过多的SOQL查询：101

=====================================触发器=========== ====================

trigger UpdateAllContacts on Account (after update) {
    for ( Account acc : Trigger.New ) {
        List<Contact> listCon = [Select id, Relationship_Category_r__c from Contact where AccountId =: acc.id];
        for ( Contact con : listCon ) {
            if ( acc.Type=='Member' ) {
                if ( con.Relationship_Category_r__c != 'Member' ) {
                    con.Relationship_Category_r__c = 'Member - staff';
                }
            } else if ( acc.Type=='Member - past ' ) {
                con.Relationship_Category_r__c = 'Member - past';
            }
        }
        try {
            update listCon;
        }
        catch (DmlException e) {}
    }
}

任何帮助将不胜感激

谢谢

Answer 1

这里有几件事让我惊讶：

• 首先是导致错误的主要原因：循环内的SOQL查询。 您需要扩展触发器以执行单个查询，而不是为更新批处理中的每个帐户记录查询一次。
• 您在同一循环中有一个DML操作（ update listCon; ），如果您在Contact触发器中碰巧有任何SOQL查询，这将使问题更加严重。 此更新也应进行批量处理，以使您进行的插入/更新次数尽可能少（在这种情况下，您可以将其限制为单个更新调用）。
• 您正在更新查询的所有联系人记录，而不管您的代码是否已更新它们。 这可能导致不必要的较长处理时间，并且可以通过在第二个列表中跟踪哪些记录应进行更新来轻松地避免这种情况。
• 这可能是设计使然，但是您抑制了更新调用中的任何错误，甚至没有尝试处理它们。 有多种方法可以执行此操作，具体取决于您的实现，因此我不会在此进行深入探讨，但是在大多数情况下，您可能至少要知道对这些记录的更新失败，因此您可以纠正此问题。

在对代码进行了一些更正之后，我们剩下了以下内容，它们使用单​​个SOQL查询，单个DML语句，并且不会更新触发器未修改的任何Contact记录：

trigger UpdateAllContacts on Account (after update) {
    List<Contact> updateCons = new List<Contact>();
    for ( Contact con : [select Id, AccountId, Relationship_Category_r__c from Contact where AccountId in :Trigger.NewMap.keySet()] ) {
        Account parentAcc = Trigger.NewMap.get(con.AccountId);
        if ( parentAcc.Type == 'Member' ) {
            if ( con.Relationship_Category_r__c != 'Member' ) {
                con.Relationship_Category_r__c = 'Member - staff';
                updateCons.add(con);
            }
        } else if ( parentAcc.Type == 'Member - past ' ) {
            con.Relationship_Category_r__c = 'Member - past';
            updateCons.add(con);
        } 
    }
    update updateCons;
}