C 中的斐波那契计算器，编译为 mips，导致无限循环

Question

我正在尝试将我的 fibonacci c 代码转换为 MIPS 汇编代码，但是，当我将 MIPS 代码运行到我的 MIPS 模拟器时，它似乎并没有结束。

代码：

int fibo(int n)
{
    if(n<2) return 1;
    else f(n-1)+f(n-2);
}

int main()
{
    fibo(5);
}

组装代码：

main: addi $sp, $sp, -4
sw $ra, 0($sp)

addi $a0, $zero, 5
jal fibo; 

lw $ra, 0($sp)
addi $sp, $sp, 4

fibo: addi $sp, $sp, -12
sw $s0, 0($sp)
sw $s1, 4($sp)
sw $ra, 8($sp)

slti $t0, $a0, 2
beq $t0, $zero, ELSE

addi $v0, $zero, 1
jr $ra

ELSE: addi $s0, $a0, 0
addi $a0, $a0, -1
jal fibo;

addi $s1, $v0, 0
addi $a0, $s0, -2
jal fibo

add $s1, $s1, $v0
j EXIT

EXIT: lw $s0, 0($sp)
lw $s1, 4($sp)
lw $ra, 8($sp)
addi $sp, $sp, 12

jr $ra

Answer 1

这里有几个问题。

首先，您的main函数缺少其终止jr $ra ，这意味着main在执行后陷入fibo 。

其次，在你的if语句中，你返回1 ，你直接调用jr $ra ，这意味着堆栈未恢复。 我通过调用j EXIT来换掉它。

最后，在 else 的末尾将f(n-1)和f(n-2)到$s1 。 此寄存器应为$v0因为您打算返回此结果。

修复后的代码如下：

main: 
    addi $sp, $sp, -4
    sw $ra, 0($sp)

    addi $a0, $zero, 5
    jal fibo

    move $a0 $v0
    li $v0 1
    syscall

    lw $ra, 0($sp)
    addi $sp, $sp, 4

    jr $ra

fibo: 
    addi $sp, $sp, -12
    sw $s0, 0($sp)
    sw $s1, 4($sp)
    sw $ra, 8($sp)


    slti $t0, $a0, 2
    beq $t0, $zero, ELSE

    addi $v0, $zero, 1
    j EXIT

    ELSE: 
        addi $s0, $a0, 0
        addi $a0, $a0, -1
        jal fibo

        addi $s1, $v0, 0
        addi $a0, $s0, -2
        jal fibo

        add $v0, $s1, $v0

    EXIT: 
    lw $s0, 0($sp)
    lw $s1, 4($sp)
    lw $ra, 8($sp)
    addi $sp, $sp, 12

    jr $ra 

Answer 2

这是我的相同代码，但它是用 RISC-V 编写的

.text

#x5 me n hai
#x7 me output
li x5 7
li x6 2
jal x1 FIB
j EXIT

FIB:
    bge x5 x6 REC 
    addi x7 x5 0
    jalr x0 0(x1)
    #Handled Base Case

REC:
    # Handling Rec. Case

    addi sp sp -12
    sw x1 0(sp)
    sw x5 4(sp)

    addi x5 x5 -1
    jal x1 FIB


    sw x7 8(sp)
    lw x5 4(sp)
    addi x5 x5 -2
    jal x1 FIB 

    lw x13 8(sp)
    add x7 x13 x7


    lw x1 0(sp)
    addi sp sp 12
    jalr x0 0(x1)

EXIT:

Answer 3

除了 Konrad ( https://stackoverflow.com/a/23185991/3729904 ) 的回答之外，我注意到您的算法中存在错误。 如果 n<2，fib 算法应该返回 n 而不是 1。

这可以修复更改行：

addi $v0, $zero, 1

进入：

add $v0, $zero, $a0