Perl打包解压和反向字节顺序

Question

我正在尝试编写脚本以在文本文件中查找十六进制字符串，并将其转换为反向字节顺序。 我遇到的麻烦是某些十六进制字符串是16位，而有些是64位。 我用过Perl的压缩包来打包和解压缩16位十六进制数字，这很好用，但是64位却不能。

print unpack("H*", (pack('I!', 0x20202032))). "\n"; #This works, gives 32202020
#This does not
print unpack("H*", (pack('I!', 0x4f423230313430343239303030636334))). "\n";

我已经尝试使用q和Q（在这里我得到ffffffffffffffffff）。 我是不是都错了？

作为背景知识，我有一个数千兆字节的管道分隔文本文件，该文件具有如上所述的反向字节顺序的十六进制字符串。 同样，文件的列也不是标准的； 有时十六进制字符串出现在一列中，有时出现在另一列中。 我需要将十六进制字符串转换为它们的反向字节顺序。

Answer 1

始终use warnings; 。 如果这样做，您将收到以下消息：

Integer overflow in hexadecimal number at scratch.pl line 8.
Hexadecimal number > 0xffffffff non-portable at scratch.pl line 8.

这些可以通过use bigint;来解决use bigint; 并将第二个数字声明更改为hex('0x4f423230313430343239303030636334') 。

但是，这个数字对于pack 'I'来说仍然太大，无法处理。

也许可以使用简单的字符串操作来完成：

use strict;
use warnings;

my @nums = qw(
    0x20202032
    0x4f423230313430343239303030636334
);

for (@nums) {
    my $rev = join '', reverse m/([[:xdigit:]]{2})/g;
    print "$_ -> 0x$rev\n"
}

__END__

输出：

0x20202032 -> 0x32202020
0x4f423230313430343239303030636334 -> 0x3463633030303932343034313032424f

或处理非偶数长度的数字：

my $rev = $_;
$rev =~ s{0x\K([[:xdigit:]]*)}{
    my $hex = $1;
    $hex = "0$hex" if length($hex) % 2;
    join '', reverse $hex =~ m/(..)/g;
}e;
print "$_ -> $rev\n"

Answer 2

为方便起见，示例中的十六进制数字为32位和128位长，而不是16和64。如果最长的十六进制数仅为64位长，则可以按照您的预期成功使用Q pack模板（提供的帽子您的perl已被编译为支持64位整数）。

pack / unpack解决方案仍然可以使用（如果添加了reverse ，则还必须从十六进制字符串中删除前导0x或从结果中修剪最后两个字符）：

print unpack "H*", reverse pack "H*", $hex_string;

您的值的示例：

perl -le 'print unpack "H*", reverse pack "H*", "4f423230313430343239303030636334"'
3463633030303932343034313032424f