Excel仅消耗70MB时出现VBA“内存不足”错误

Question

问：为什么我的系统有足够的内存（办公室为64位）时内存不足？

问：可能是拆分时的数据导致了这种奇怪的行为吗？

问：如果拆分该字符串会造成麻烦，那么如何仅出于存储/恢​​复该字符串的操作而对其进行清理/恢复？

规格： Win 8.1 Pro + Office 2013 64bit，系统中有8GB RAM

这是代码，仅获取单个LARGE（〜1-2MB）字符串，并将其拆分为多个单元格，因此每个单元格限制32k个字符不会造成危害：

Public Sub SaveConst(str As String)
    Dim i As Long
    i = 0
    ' Clear prior data
    Do While LenB(Range("ConstJSON").Offset(0, i)) <> 0
        Range("ConstJSON").Offset(0, i) = ""
        i = i + 1
    Loop

    Dim strLen As Long

    With Range("ConstJSON")
        .Offset(0, 0) = Left$(str, 30000)
        i = 1
        strLen = Len(str)
        Debug.Print strLen
        Do While strLen > i * 30000
            .Offset(0, i) = Mid$(str, i * 30000 + 1, 30000)
            Debug.Print i
            i = i + 1
        Loop
    End With
End Sub

现在，Len（str）报告了约27万个字符，而我最多进行了4次迭代，然后出现了“内存不足”错误。

现在，这是该位置的错误的第n次迭代。 但是我已经简化/修改了代码，以便有时可以工作。 对于完全相同的数据集。

更新：Thx到Jean代码，我相信它保存到导致该错误的单元的部分字符串。

.Offset(0, i) = Mid$(str, i * 30000 + 1, 30000)

要么

Range("ConstJSON").Resize(nPieces).Value2 = v

两者都会导致错误。

更新2：我将该字符串保存到单个单元格而没有大惊小怪。 但是现在该字符串变得太大而无法容纳，分裂有时会导致该错误“内存不足”。 示例字符串：

[...]“” ebiZlecenias“”：[{“” id“”：“” 91a75940-6d3e-06f8-bcf7-28ecd49e85f2“”，“” lp“”：null，“” name“”：“” ZLECENIE GŁÓWNE“”，“” date_entered“”：“” 2014-04-15 08:13:18“”，“” date_modified“”：“”“ 2014-04-15 08:13:18”“，”“ modified_user_id” “：”“ 2”“，”“ budowa_id”“：”“ 8614aab5-29da-ffac-4865-e8c5913c729c”“，”“ rodzaj”“：”“ 1”“，”“ etap”“：”“ 1” “，”“ data_akceptacji”“：null，”“ opis”“：null，”“ user_id”“：null，”“ data_bazowa_od”“：null，”“ data_bazowa_do”“：null，”“ data_rzeczywista_od”“：null， “” data_rzeczywista_do“”：空，“” archiwalny“”：空，“”已删除“”：空，“” termin_raportowania“”：空，“” okres_raportowania“”：空，[...]

Answer 1

值得一试：首先将字符串分成一个数组，然后将整个数组立即拍打到工作表上。

Const pieceLength As Long = 3000
Dim s As String
Dim i As Long
Dim nPieces As Long
Dim v As Variant
s = ... ' whatever your string is...
nPieces = WorksheetFunction.Ceiling(Len(s) / pieceLength, 1)
ReDim v(1 To nPieces, 1 To 1)
For i = 1 To nPieces
    v(i, 1) = Mid(s, (pieceLength * i) + 1, pieceLength)
Next i
Range("ConstJSON").Resize(nPieces).Value2 = v

我尚未测试您的代码，因此无法确切地说出问题所在，但我知道一次写入单个单元（或从单个单元读取）是缓慢且昂贵的。 通常最好将大量的单元格读入数组或从数组中写入，并操纵数组（而不是单元格）。

Answer 2

编辑：我相信您的标本字符串的问题是某些子字符串以“-”开头。 发生这种情况时，Excel认为内容是一个公式，这就是导致错误的原因。 将单元格预先设置为文本格式不能解决问题，但是在每个条目之前加一个“单引号”可以将条目强制为文本，并且不会显示在公式栏中，除非在公式栏中显示，似乎已解决了我宏中的问题，即使将上面的样本字符串用作“基本”字符串也是如此。

EDIT2：似乎正在发生的事情是，如果字符串长度大于8,192个字符（公式中允许的最长字符），并且还以使Excel认为它可能是公式的标记开头（例如：-，+， =）， 即使将单元格设置为文本格式，写入单元也将失败，并显示内存不足错误。 如果首先插入单引号，则不会发生这种情况。

下面是一些适用于更长字符串的代码。

下面的代码首先创建一个长字符串，在这种情况下，该字符串略大于100,000,000个字符，然后将其拆分为连续的列。 没有错误：

Option Explicit
Sub MakeLongString()
    Dim S As String
    Const strLEN As Long = 100 * 10 ^ 6
    Const strPAT As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"

S = strPAT
Do
    S = S & S
Loop Until Len(S) > strLEN
Debug.Print Format(Len(S), "#,###")

SplitString (S)
Debug.Print Range("a1").End(xlToRight).Column

End Sub

Sub SplitString(STR)
  Dim R As Range
  Dim strLEN As Long
  Set R = [a1]
  Dim I As Long
strLEN = Len(STR)
Do Until I > strLEN
    R(1, I / 30000 + 1) = "'" & Mid(STR, I + 1, 30000)
    I = I + 30000
Loop
End Sub

我只是运行了一个测试，其中要写入的范围是一个多单元格范围，并且像您一样通过Offset方法设置了目标，并且它也运行无误地完成了，填充了前四行。

Sub SplitString(STR)
  Dim R As Range
  Dim strLEN As Long
  Set R = [a1:a4]
  Dim I As Long
strLEN = Len(STR)
Do Until I > strLEN
    R.Offset(, I / 30000) = "'" & Mid(STR, I + 1, 30000)
    I = I + 30000
Loop
End Sub