如何使用printf调试linux内核的汇编代码

Question

这是我试图通过putf / printk语句调试的文件。

代码是汇编。

 79         __HEAD
 80 ENTRY(stext)
 81  ARM_BE8(setend be )                    @ ensure we are in BE8 mode
 82 
 83  THUMB( adr     r9, BSYM(1f)    )       @ Kernel is always entered in ARM.
 84  THUMB( bx      r9              )       @ If this is a Thumb-2 kernel,
 85  THUMB( .thumb                  )       @ switch to Thumb now.
 86  THUMB(1:                       )
 87 
 88 #ifdef CONFIG_ARM_VIRT_EXT
 89         bl      __hyp_stub_install
 90 #endif
 91         @ ensure svc mode and all interrupts masked
 92         safe_svcmode_maskall r9
 93 
 94         mrc     p15, 0, r9, c0, c0              @ get processor id
 95         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
 96         movs    r10, r5                         @ invalid processor (r5=0)?
 97  THUMB( it      eq )            @ force fixup-able long branch encoding
 98         beq     __error_p                       @ yes, error 'p'
 99 
100 #ifdef CONFIG_ARM_LPAE
101         mrc     p15, 0, r3, c0, c1, 4           @ read ID_MMFR0
102         and     r3, r3, #0xf                    @ extract VMSA support
103         cmp     r3, #5                          @ long-descriptor translation table format?
104  THUMB( it      lo )                            @ force fixup-able long branch encoding
105         blo     __error_lpae                    @ only classic page table format
106 #endif
107 
108 #ifndef CONFIG_XIP_KERNEL
109         adr     r3,

我只是想从这个文件中将一些消息发送到控制台。 此代码适用于ARM。

我尝试在这样的代码块中使用printk但是无法编译。

有什么建议？

Answer 1

答案在ARM启动FAQ中给出。 您需要启用配置菜单项Kernel Hacking | Kernel低级调试功能 。 例如，代码__error_p将在控制台UART上显示一些内容。 例如，当内核无法与您的计算机ID匹配时， elinux.org的打印调试会显示错误消息。 ^{请参阅： ARM引导文档}

DEBUG_LL创建函数extern void printascii(char *); 你也可以使用vprintk_emit() 。

--- a/kernel/printk/printk.c
+++ b/kernel/printk/printk.c
@@ -1483,6 +1483,8 @@ static size_t cont_print_text(char *text, size_t size)
        return textlen;
 }

+extern void printascii(char*);
+
 asmlinkage int vprintk_emit(int facility, int level,
                            const char *dict, size_t dictlen,
                            const char *fmt, va_list args)
@@ -1541,6 +1543,7 @@ asmlinkage int vprintk_emit(int facility, int level,
         * prefix which might be passed-in as a parameter.
         */
        text_len = vscnprintf(text, sizeof(textbuf), fmt, args);
+       printascii(text);

        /* mark and strip a trailing newline */
        if (text_len && text[text_len-1] == '\n') {

这和内核命令行initcall_debug将有助于诊断引导问题。

如果您的平台不支持DEBUG_LL ，则实现支持它所需的轮询UART例程相当容易。

通常， printk()在早期启动期间进行缓冲，并且在控制台驱动程序处于活动状态之前不会实际打印出来。 因此，在不修补vprintk_emit() ，您可以在UART驱动程序运行之前的任何位置崩溃/暂停，并且在正常配置下看不到任何内容。

对于head.S等的调试，你需要在汇编程序中执行此操作。 error_p实现有一些示例代码，这是另一个，

 #ifdef CONFIG_DEBUG_LL
         /* Save some registers? */
         adr     r0, prefix
         bl      printascii
         mov     r0, r9
         bl      printhex8
         adr     r0, tail
         bl      printascii
         b       1f
 prefix: .asciz  "\nTrace 1 gives "
 tail:   .asciz  "\n"
 1:  /* Perhaps halt here, due to register clobbers */
 #endif

根据head.S中的上下文，您在寄存器的使用方面受到限制。 通常，此代码的唯一问题是您没有执行ARM启动文档中描述的操作。

您也可以直接使用arch / arm / include / debug中定义的宏。 宏是，

• addruart - 获取参数1（phys），2（virt）的addruart地址，（第三个是宏的tmp）。
• senduart - 将字符参数1写入地址（虚拟或物理）。
• waituart - parm 1（tmp），param 2地址（virt或phys）。 准备？
• busyuart - parm 1（tmp），param 2地址（virt或phys）。 空的？

您可以在printasii()的实现中看到正在使用的API。

ENTRY(printascii)
        addruart_current r3, r1, r2   @ phys address to r3
        b   2f
1:      waituart r2, r3   @ ready (r2 is tmp, r3 is phys address)
        senduart r1, r3   @ transmit r1 character
        busyuart r2, r3   @ wait for character to finish tx.
        teq r1, #'\n'
        moveq   r1, #'\r' @ insert carriage return if new line.
        beq 1b
2:      teq r0, #0    @ NULL pointer?
        ldrneb  r1, [r0], #1  @ next char
        teqne   r1, #0        @ end of string?
        bne     1b            @ send another.
        mov pc, lr
ENDPROC(printascii)

在head.S和其他的汇编程序中，您可以使用具有各种寄存器参数的宏来避免使用中的寄存器（如r0-r3 。 它们通常可以使用， printascii()可以直接调用。