Modelica：阶跃函数的初始条件

Question

我想问一个Modelica有关何时函数的问题，并且以下源代码无法正常运行。 变量Pstart_CONV是if语句中der（x_calc）的初始条件，并且当“ when语句”变为true时，Pstart_CONV值由x给出。 因为x是一个阶跃函数，所以我想为der（x_calc）分配一个初始条件，以便可以在整个域中继续使用x。

非常感谢你，

资源：

model Unnamed4
  Real  Pstart_CONV;

  Real P_crit_ratio;
  parameter Real P_crit_ratio_criteria = 2.00;

  Real x;
  Real x_calc(start=0);

equation 
  P_crit_ratio = 10-time;

  when P_crit_ratio <= P_crit_ratio_criteria then
    Pstart_CONV = x;
  end when;

  if P_crit_ratio >= P_crit_ratio_criteria then
    x = time^2;
    x_calc = 0;
  else
    der(x_calc) = time * 5;
    x = x_calc + Pstart_CONV;
  end if;   
end Unnamed4;

Answer 1

我看到这段代码有两个问题。 主要问题与以下事实有关：这就是所谓的“变量索引”问题。 我会解决的。 但是首先，我想指出您的if和when子句未正确同步。 我的意思是，由if语句表示的行为更改不一定会在激活when子句的同一时刻发生。

为了解决这个问题，您可以轻松地将模型重构为如下所示：

model Model1
  Real Pstart_CONV;
  Real P_crit_ratio;
  parameter Real P_crit_ratio_criteria=2.00;
  Real x;
  Real x_calc(start=0);
  Boolean trigger(start=false);
equation 
  P_crit_ratio = 10-time;

  when P_crit_ratio <= P_crit_ratio_criteria then
    Pstart_CONV = x;
    trigger = true;
  end when;

  if trigger then
    der(x_calc) = time * 5;
    x = x_calc + Pstart_CONV;
  else
    x_calc = 0;
    x = time^2;
  end if;
end Model1;

现在，将if和when子句都绑定到trigger变量。 现在我们可以解决您的主要问题，即在if语句的一侧，您有：

der(x_calc) = time * 5;

...而在另一边，您有：

x_calc = 0;

在实践中，这意味着对于模拟的一部分，您x_calc使用微分方程求解x_calc而在模拟的另一部分中，您x_calc使用代数方程求解x_calc 。 这导致“变量索引”问题，因为DAE的“索引”根据trigger的值是true还是false而变化。

一种解决方法是稍微修改方程式。 代替使用方程x_calc = 0我们为x_calc指定初始条件0 ，然后执行一个微分方程，该方程表示x_calc的值不变， 即 der(x_calc) = 0 。 换句话说，通过删除将x_calc设置为常数的代数方程并将其替换为将x_calc的初始值设置为所需值的方程，然后添加一个实际上表示简单的微分方程的方程，可以得到相同的行为。 x_calc的值不变。

根据您的情况进行此类更改会导致以下模型：

model Model2
  Real Pstart_CONV;
  Real P_crit_ratio;
  parameter Real P_crit_ratio_criteria=2.0;
  Real x;
  Real x_calc(start=0);
  Boolean trigger(start=false);
initial equation
  x_calc = 0;
equation
  P_crit_ratio = 10-time;

  when P_crit_ratio <= P_crit_ratio_criteria then
    Pstart_CONV = x;
    trigger = true;
  end when;

  if trigger then
    der(x_calc) = time * 5;
    x = x_calc + Pstart_CONV;
  else
    der(x_calc) = 0;
    x = time^2;
  end if;
end Model2;

我对其进行了测试，并且该模型使用SystemModeler进行了运行（尽管我对您的问题或期望的结果了解得不足以真正验证结果）。

希望对您有所帮助。