将XML文件导入InDesign时出现命名空间错误

Question

任务是在使用XSL转换处理XML文件的同时将其导入InDesign CS6。 为了将段落样式应用于导入的文本，通过XSLT添加了属性“ aid：pstyle”。 一个非常简单的例子：

要导入的XML文件：

<?xml version="1.0" encoding="UTF-8"?>
<Root>
   <Paragraph>This is my first XML-Import.</Paragraph>
</Root>

XSL转换：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:aid="http://ns.adobe.com/AdobeInDesign/4.0/"
    version="2.0">

    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/">
        <xsl:apply-templates/>
    </xsl:template>

    <xsl:template match="Paragraph">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:attribute name="aid:pstyle">
               <xsl:value-of select="'myParagraphStyle'"/>
            </xsl:attribute>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*|node()|comment()|processing-instruction()">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

在输入文件上外部运行XSLT，我们得到

<?xml version="1.0" encoding="UTF-8"?>
<Root>
    <Paragraph xmlns:aid="http://ns.adobe.com/AdobeInDesign/4.0/" aid:pstyle="myParagraphStyle">This is my first XML-Import.</Paragraph>
</Root>

可以将其导入InDesign并获得所需的结果。 但是，当我们导入主要输入并在导入期间应用XSLT 时 ，InDesign会抱怨名称空间错误。 错误消息是“ DOM-Transformationsfehler：Ungültiges命名空间”（我们有德语InDesign版本，在英语中应该有点像“ DOM-Transformation错误：非法名称空间”。）

有什么线索如何在对导入应用XSLT的同时导入我的XML？

Answer 1

首先，我以为您为xmlns：aid使用了错误的名称空间IRI，但在重新查看其他示例时，我发现“ http://ns.adobe.com/Adobe InDesign / 4.0 /”以及一个额外的空白和“ http：// ns .adobe.com / Adob​​eInDesign / 4.0 / 。 实际上，后者似乎是正确的，因为插件SDK具有匹配的定义。

然后样式表version =“ 2.0”显得有点大胆，我将其更改为“ 1.0”，但仍未导入。

最终我明白了：InDesign对名称空间非常挑剔。 显然，必须在根元素处引入名称空间。 以下版本可用于我的InDesign CS6：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:aid="http://ns.adobe.com/AdobeInDesign/4.0/" version="1.0">

    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/">
        <xsl:apply-templates/>
    </xsl:template>

    <xsl:template match="Root">
        <Root xmlns:aid="http://ns.adobe.com/AdobeInDesign/4.0/">
            <xsl:apply-templates/>
        </Root>
    </xsl:template>

    <xsl:template match="Paragraph">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:attribute name="aid:pstyle">
                <xsl:value-of select="'myParagraphStyle'"/>
            </xsl:attribute>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*|node()|comment()|processing-instruction()">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>