对于unicode Delphi，TStream到TStringList失败

Question

如下面代码的Test2所示，TStringList被转换为TStream，然后TStream被转换回TStringList。 但是，在Delphi 7中， Test2给出了与Test1相同的功能。 在unicode Delphi中， Test2没有给出正确的结果。 你能帮忙建议出现什么问题吗？

program Project1;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  Classes, SysUtils;

// http://stackoverflow.com/questions/732666
// Converting TMemoryStream to String in Delphi 2009
function MemoryStreamToString(M: TMemoryStream): string;
begin
  SetString(Result, PChar(M.Memory), M.Size div SizeOf(Char));
end;

procedure Test1;
var
  SrcList: TStrings;
  S: String;
  AStream: TStream;
begin
  SrcList := TStringList.Create;
  try
    with SrcList do
    begin
      Add('aa');
      Add('bb');
      Add('cc');
    end;

    S := SrcList.Text;

    AStream := TMemoryStream.Create;
    try
      // AStream.Write(S[1], Length(S));
      // AStream.Write(S[1], Length(S) * SizeOf(Char));
      AStream.Write(Pointer(S)^, Length(S) * SizeOf(Char));

      WriteLn(MemoryStreamToString(TMemoryStream(AStream)));
    finally
      AStream.Free;
    end;
  finally
    SrcList.Free;
  end;
end;

procedure Test2;
var
  SrcList: TStrings;
  S: String;
  AStream: TStream;
  DestList: TStringList;
  I: Integer;
begin
  SrcList := TStringList.Create;
  try
    with SrcList do
    begin
      Add('aa');
      Add('bb');
      Add('cc');
    end;

    S := SrcList.Text;

    AStream := TMemoryStream.Create;
    try
      // AStream.Write(S[1], Length(S));
      // AStream.Write(S[1], Length(S) * SizeOf(Char));
      AStream.Write(Pointer(S)^, Length(S) * SizeOf(Char));

      DestList := TStringList.Create;
      try
        AStream.Position := 0;
        DestList.LoadFromStream(AStream);

        WriteLn(DestList.Text);
      finally
        DestList.Free;
      end;
    finally
      AStream.Free;
    end;
  finally
    SrcList.Free;
  end;
end;

begin
  try
    Test1;
    Test2;
  except
    on E: Exception do
      WriteLn(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

Answer 1

Test1将原始String数据按原样写入TMemoryStream ，然后将其原样读回String ，因此所有版本的Delphi中都能正确匹配。 由于类似的原因， Test2在Delphi 2007及更早版本中运行。

在Delphi 2009及更高版本中， Test2失败了，因为您没有考虑到TStrings.LoadFrom...() （以及TStrings.SaveTo...() ）在这些版本的Delphi中是TEncoding -aware。 你正在编写UTF-16编码数据到TMemoryStream在前面没有BOM，然后你不告诉LoadFromStream()该流为UTF-16编码。 它试图找到一个BOM，当它找不到时，它会使用TEncoding.Default （又名8bit Ansi）加载流（为了向后兼容遗留代码）。

因此，在此示例中，您需要在Delphi 2009及更高版本中加载流数据时指定正确的流数据编码：

DestList.LoadFromStream(AStream, TEncoding.Unicode);