使用awk或sed替换字符串中的字符

Question

给定下面的字符串，我如何通过使用awk或sed获取第14和15位数字来替换第6和第7位。

xxxxx02xxxxxx89xx
xxxxx22xxxxxx33xx

输出

xxxxx89xxxxxx89xx
xxxxx33xxxxxx33xx

我是新手，对不起我的问题。

Answer 1

sed命令很简单，但是很难阅读：

sed 's/\(.....\)..\(......\)\(..\)/\1\3\2\3/'

Gnu awk可能有一个可能更具维护性的解决方案（但其他awk品种则没有。但是，请参见下文）：

gawk -v FIELDWIDTHS="5 2 6 2 999" -v OFS='' '{$2=$4;print}'

FIELDWIDTHS变量定义5个固定宽度的字段：前5个字符，后两个字符（位置6和7）； 接下来的六个字符（8到13）； 接下来的两个字符（14和15）； 下一个（最多）999个字符，应为该行的其余部分。 （如果您的行较长，请根据需要增加）。 对于固定长度的字段，将OFS设置为空通常很有用。 它防止awk在输出的字段之间插入空格。

FIELDWIDTHS是GNU awk扩展。 但是，在Posix awk重新实现很容易。 这是一个简单的实现：

function fieldwidth_set(         i) {
  if (PROCINFO["FS"]) FIELDWIDTHS = FIELDWIDTHS;
  else if (length(FIELDWIDTHS)) {
    _FW_NF = split(FIELDWIDTHS, _FW_ARRAY);
    for (i in _FW_ARRAY) {
      if (_FW_ARRAY[i] !~ /^[0-9]+$/) {
        printf "Illegal value '%s' in FIELDWIDTHS\n", _FW_ARRAY[i] >>"/dev/stderr";
        exit 1;
      }
      _FW_ARRAY[i]+=0;
    }
  } else
    _FW_NF = 0;
}
function set_fieldwidth(fw) { FIELDWIDTHS=fw; fieldwidth_set(); }
function fw_(               a,i,k) {
  if (_FW_NF) {
    a = $0;
    $0 = "";
    k=1;
    for (i=1; i<=_FW_NF; ++i) { 
      $i = substr(a, k, _FW_ARRAY[i]);
      k+=_FW_ARRAY[i];
    }
  }
}
BEGIN{set_fieldwidth()}
{fw_()}

据我所知，只有Gnu awk允许您在awk命令行上混合程序文件和程序文本。 Posix要求使用-f program-file选项，该选项可以重复，但不要求由Gnu awk实现的-e program-text选项。 因此，如果要将上述代码段与命令行awk程序一起使用，则需要执行以下操作：

awk -v FIELDWIDTHS="5 2 6 2 999" -v OFS= -f fw.awk -f <(echo '{$2=$4;print}')

（假设您将fieldwidth代码段放入fw.awk 。）

为了提高效率， fw.awk坚持要求您通过调用fieldwidth_set()告诉您已更改FIELDWIDTHS 。 或者，您可以使用set_fieldwidth("....")将FIELDWIDTHS设置为新值。 它将与GNU awk以及其他awk实现一起使用； 它使GNU awk可以完成繁重的工作。

Answer 2

您可以尝试以下sed命令，

$ echo 'xxxxx03xxxxxx75xx' | sed -r 's/^(.{5})(..)(.{6})../\1\2\3\2/g' 
xxxxx03xxxxxx03xx
$ echo 'xxxxx03xxxxxx75xx' | sed  's/^\(.\{5\}\)\(..\)\(.\{6\}\)../\1\2\3\2/g'
xxxxx03xxxxxx03xx

用第6位和第7位的数字替换第14位和第15位数字。

$ echo 'xxxxx03xxxxxx75xx' | sed -r 's/^(.{5})..(.{6})(..)/\1\3\2\3/g'
xxxxx75xxxxxx75xx
$ echo 'xxxxx03xxxxxx75xx' | sed 's/^\(.\{5\}\)..\(.\{6\}\)\(..\)/\1\3\2\3/g'
xxxxx75xxxxxx75xx

它将第6和7位数字替换为第14和15位的数字。

Answer 3

这应该按照您的要求并与所有awk ：

awk '{$6=$14;$7=$15}1' FS= OFS= file
xxxxx89xxxxxx89xx
xxxxx33xxxxxx33xx

它将位置6的数字更改为14的一位，并用1的整数15更改为7的一位。

如果FS=""不起作用，请尝试以下操作：

awk '{n=split($0,a,"");a[6]=a[14];a[7]=a[15];for (i=1;i<=n;i++) printf "%s",a[i];print ""}' input

---

根据评论之一的要求：
It works, thanks! How about if I want to replace 14th and 15th digit by 6th and 7th digit? – Vision111

awk '{$14=$6;$15=$7}1' FS= OFS= file

Answer 4

这将在没有GNU awk GAWK情况下起作用

awk 'sub(/[0-9]+/,substr($0,14,2))' file

更长或更通用

awk '{print substr($0,0,5) substr($0,14,2) substr($0,8)}' file

结果：

xxxxx89xxxxxx89xx
xxxxx33xxxxxx33xx