如何使用批处理脚本使用另一个目录的子文件夹名称在目录中创建新的空文件夹？

Question

我的主要目标是在REPOS文件夹中备份SVN存储库。 由于“ svnadmin hotcopy”必须同时具有源文件夹和目标文件夹，因此我需要在其他目录中使用folderName_backup的名称创建新文件夹，然后使用“ svnadmin hotcopy”进行复制。 顺便说一句，这必须在Windows批处理文件中完成。 我这部分的代码如下：

for /d %%X in (%source%\*) do (
 md %destination%\%%X_backup
 svnadmin hotcopy %%X %destination%\%%X_backup

 )

运行此代码后，我得到错误消息：文件名，目录名称或卷标签语法不正确。

Answer 1

set "source=c:\where\the\folders\are"
set "destination=c:\where\the\backup\will\be"

for /d %%a in ("%source%\*") do for %%b in ("%destination%\%%~nxa_backup") do (
    if not exist "%%~fb\" md "%%~fb" 
    if exist "%%~fb\" svnadmin hotcopy "%%~fa" "%%~fb"
)

%%~fb是%%b引用的文件/文件夹的完整路径。 相当于%%~fa 。 %%~nxa是%%a引用的文件/文件夹的名称和扩展名。

该代码将所有路径都用引号引起来，以避免空格问题，并在创建和备份之前测试文件夹是否存在

您可以删除for %%b的内部文件，并在md和svnadmin命令中使用组成的目标文件夹（如您的代码中所示），但是此附加for仅允许编写一次定义目标文件夹的方式。

Answer 2

for /f "tokens=*" %%G in ('dir /b /a:d "%Source%"') do (
    md %destination%\%%G

    svnadmin hotcopy %Source%\%%G %Destination%\%%G 
 )

旧解决方案的问题在于，它不是在目录中获取文件夹名称，而是获取目录的子目录。 这就是为什么结果类似于C:\\where\\the\\backup\\will\\be\\C:\\where\\the\\folders\\are

这就是我得到错误的原因：文件名，目录名称或卷标签语法不正确。 我上面在回答中与您共享的脚本部分（工作正常）将子目录标记化以获取文件夹名称并使用它。