Neo4j-Cypher：具有遍历关系的共同对象

Question

我有一个小图：

CREATE 
(Dic1:Dictioniary { name:'Dic1' }),
(Dic2:Dictioniary { name: 'Dic2' }),
(Dic3:Dictioniary { name: 'Dic3' }),
(File1:File { name: 'File1' }),
(File2:File { name: 'File2' }),
(File3:File { name: 'File3' }),
(Dic2)-[:contains]->(Dic1),
(Dic1)-[:contains]->(File1),
(Dic3)-[:contains]->(File2),
(File1)-[:references]->(File3),
(File2)-[:references]->(File3)

我需要一个密码查询来找出，例如Dic2和Dic3是否具有路径/关系，它们引用相同的文件。 在这种情况下，这将是正确的； 相互的文件是File3。

谢谢你的帮助

Answer 1

当您只寻找两个词典时，可以在一个语句中实现：

MATCH (d2:Dictioniary { name:'Dic2' }),(d3:Dictioniary { name:'Dic3' })
MATCH (d2)-[:contains|references*]->(f:File)<-[:contains|references*]-(d3)
RETURN f

由于两个无限制的路径匹配，因此它非常昂贵，但是由于它是由两个字典匹配从一开始就绑定的，因此它非常便宜。

如果您有任意数量的“字典”进行测试，则可以执行以下操作：

MATCH (d1:Dictioniary { name:'Dic1' }),(d2:Dictioniary { name:'Dic2' }),(d3:Dictioniary { name:'Dic3' })
WITH [d1,d2,d3] AS ds
MATCH (d)-[:contains|references*]->(f:File)
WHERE d IN ds
WITH f, ds, COLLECT(d) AS fds
WHERE length(ds)= length(fds)
RETURN f

这将与您首先感兴趣的字典相匹配，然后依次为每个字典查找它们引用的文件。 重要的是保留File对象，并将引用该对象的Dictionary收集到一个数组（ fds ）中。 如果我们知道我们有3个以（ length(ds) ）开头的字典，并且给定的文件具有相同数量的相关字典（ length(fds) ），则所有字典都必须引用它。

假设从给定字典到给定文件的路径可能有多个，则可以将DISTINCT修饰符插入第二个WITH语句：

WITH f, ds, COLLECT(DISTINCT(d)) AS fds