在Haskell中通过构造函数对数据类型进行分组

Question

给定此数据类型

data Val = X Int | Y Bool | Z Double deriving (Eq, Show)

以及诸如的列表

let vals = [X 1, Z 2.7, Y True, X 2, Z 3.14, Y True]

如何将vals元素分组到这个列表中，

[[X 1,X 2],[Y True,Y True],[Z 2.7, Z 3.14]]

Answer 1

要添加到@ RamonSnir的答案，还可以使用“Scrap the boilerplate”框架自动构建用于按构造函数对数据类型进行分组的函数：

{-# LANGUAGE DeriveDataTypeable #-}

import Data.Data
import Data.Function (on)
import Data.List (groupBy, sort)

data Val = X Int | Y Bool | Z Double
  deriving (Eq, Ord, Show, Typeable, Data)

vals :: [Val]
vals = [X 1, Z 2.7, Y True, X 2, Z 3.14, Y True]

main :: IO ()
main = print $ groupBy (on (==) toConstr) $ sort vals

两个重要部分是：

• 派生可Typeable和Data ，和
• 使用toConstr来获取特定值中使用的构造函数的表示。

Answer 2

我有以下几点：

data Val = X Int | Y Bool | Z Double deriving (Eq, Ord, Show)

vals :: [Val]
vals = [X 1, Z 2.7, Y True, X 2, Z 3.14, Y True]

valCtorEq :: Val -> Val -> Bool
valCtorEq (X _) (X _) = True
valCtorEq (Y _) (Y _) = True
valCtorEq (Z _) (Z _) = True
valCtorEq _ _ = False

然后：

*Main Data.List> groupBy valCtorEq $ sort vals
[[X 1,X 2],[Y True,Y True],[Z 2.7,Z 3.14]]

Answer 3

（这可能是极端矫枉过正，但修补它是一个有趣的问题！）

提供的答案有3个小问题：

• 如果所考虑的类型不在Ord （例如，某处有某个函数）会怎么样？
• 此外，该操作是否应该在列表的长度为O（n log n）？
• 最后，提供的示例不足以确定分组是否应该是稳定的，即：分组[X 2, X 1]的结果应该是[X 1, X 2] （如果您使用的话，那就是你得到的结果）基于sort的解决方案）或元素应保持原始顺序？

所以这是我能提出的最通用的解决方案。 它是稳定的，它不需要Ord （事实上​​你甚至不需要触摸原始数据类型）并且它运行在大约O（n * min（n，W））时间，其中W是机器的字大小（在我的身上，它是64）。 也就是说，一旦列表比64-ish元素更长，它就是线性的（我说'约'，因为分组的元素仍然需要从差异列表重构）。

{-# LANGUAGE DeriveDataTypeable, StandaloneDeriving #-} 

import Data.Data
import qualified Data.IntMap as IM

groupByConstructor :: Data a => [a] -> [[a]]
groupByConstructor = map ($ []) . IM.elems . IM.fromListWith (flip (.)) 
    . map (\a -> (constrIndexOf a, (a:))) where constrIndexOf = constrIndex . toConstr

-- definition of Val as originally posed, without Ord:
data Val = X Int | Y Bool | Z Double deriving (Eq, Show)

deriving instance Typeable Val
deriving instance Data Val

-- new example:
vals = [X 2, Z 2.7, Y True, X 1, Z 3.14, Y False, Z 0.2]

现在groupByConstructor vals给出了[[X 2, X 1],[Y True, Y False],[Z 2.7, Z 3.14, Z 0.2]] ，我认为应该如此。

---

它不适用于对Int s， Char s， Float或不可表示类型（如Ptr和Array列表进行排序。 通过使用一种算法可以使效率更高一些，该算法使用可能的构造函数来进一步推动线性常量，但IntMap现在必须这样做:-)