As3错误：错误＃1009：无法访问空对象引用的属性或方法

Question

我的库存系统似乎有错误。

这是我的课：

package 
{
    import flash.display.*;

    public class InventoryDemo extends MovieClip
    {
        var inventory:Inventory;

        public function InventoryDemo()
        {
            inventory = new Inventory(this);
            inventory.makeInventoryItems([d1,d2]);
        }
    }
}

我已经在另一个关键帧中放置了d1和d2对象。

这是子类：

package 
{
    import flash.display.*;
    import flash.events.*;

    public class Inventory
    {
        var itemsInInventory:Array;
        var inventorySprite:Sprite;

        public function Inventory(parentMC:MovieClip)
        {
            itemsInInventory = new Array  ;
            inventorySprite = new Sprite  ;
            inventorySprite.x = 50;
            inventorySprite.y = 360;
            parentMC.addChild(inventorySprite);

        }
        function makeInventoryItems(arrayOfItems:Array)
        {
            for (var i:int = 0; i < arrayOfItems.length; i++)
            {
                arrayOfItems[i].addEventListener(MouseEvent.CLICK,getItem);
                arrayOfItems[i].buttonMode = true;
            }
        }

        function getItem(e:Event)
        {
            var item:MovieClip = MovieClip(e.currentTarget);
            itemsInInventory.push(item);
            inventorySprite.addChild(item);
            item.x = itemsInInventory.length - 1 * 40;
            item.y = 0;
            item.removeEventListener(MouseEvent.CLICK,getItem);
            item.addEventListener(MouseEvent.CLICK,useItem);
        }

        function useItem(e:Event)
        {
            var item:MovieClip = MovieClip(e.currentTarget);
            trace(("Use Item:" + item.name));
        }
    }
}

当我在只有d1和d2的黑色项目中尝试该代码时，该代码将起作用。 谁能帮我解决这个问题？

Answer 1

您的错误提示您调用时未创建d1和d2

inventory.makeInventoryItems([d1,d2]);

您建议您在第二个关键帧中创建了d1和d2，但是如果InventoryDe​​mo是您的DocumentClass，则它将在到达第二个关键帧之前运行。

因此，如果要使用d1和d2，则需要将它们移动到第一帧，或者直到出现影片的第二帧之前，才需要尝试使用它们。

如果要将d1和d2保留在第二个框架中，则需要将调用从构造函数中取出，并转到在第二个框架中调用的新函数中：

public function InventoryDemo()
{
    //Do nothing here
    //inventory = new Inventory(this);
    //inventory.makeInventoryItems([d1,d2]);
}

public function initialiseInventory():void
{
    //Initialise you inventory here.
    inventory = new Inventory(this);
    inventory.makeInventoryItems([d1,d2]);
}

然后在时间轴的第二帧上调用该函数：

initialiseInventory();
stop();