添加bison / jison计算器语言的功能

Question

我正在尝试使用一些简单的函数来扩展Jison计算器示例 。 我对解析和野牛/ jison很新，但这是我到目前为止的一点点：

/* lexical grammar */
%lex

%{
  var funcs = {
    pow: function(a, b) { return Math.pow(a, b); },
    test: function(a) { return a*2; }
  }
%}

%%

\s+                   /* skip whitespace */
[0-9]+("."[0-9]+)?\b  return 'NUMBER'
[a-zA-Z]+             return 'NAME'
","                   return ','
"*"                   return '*'
"("                   return '('
")"                   return ')'
<<EOF>>               return 'EOF'
.                     return 'INVALID'

/lex

%start expressions

%% /* language grammar */
expressions
    : e EOF
      { return $1; }
    ;

expression_list
    : expression_list ',' e
    | e
    ;

e
    : e '*' e
        {$$ = $1*$3;}
    | '(' e ')'
        {$$ = $2;}
    | NUMBER
        {$$ = Number(yytext);}
    | NAME '(' expression_list ')'
        {$$ = funcs[$NAME]($expression_list);}
    ;

问题是函数只传递一个参数。 例如：

test(2) -> 4
pow(2,3) -> null

实际上，如果你在console.log中使用pow的参数，那么看起来b甚至都没有定义。 为什么在将它发送到函数之前不解析整个表达式列表？

Answer 1

以下代码执行您要求的操作。 突出点：

1. expression_list的规则现在构建了一个实际的值列表，用于被调用的函数。

2. 通过建立的列表expression_list被传递到apply ，使他们成为功能被称为参数（ undefined是那里设置的值的第一个参数this对undefined ）。

3. 我已经为expression的操作添加了一个console.log指令，这样当我在命令行运行生成的解析器时，我会看到发生了什么。

4. 我已经将funcs的定义移到了一开始。 在哪里jison只是没有把它放在最终文件中的正确位置。

这是最终文件：

%{var funcs = {
    pow: function(a, b) { return Math.pow(a, b); },
    test: function(a) { return a*2; }
  }
%}

/* lexical grammar */
%lex

%%

\s+                   /* skip whitespace */
[0-9]+("."[0-9]+)?\b  return 'NUMBER'
[a-zA-Z]+             return 'NAME'
","                   return ','
"*"                   return '*'
"("                   return '('
")"                   return ')'
<<EOF>>               return 'EOF'
.                     return 'INVALID'

/lex

%start expressions

%% /* language grammar */
expressions
    : e EOF
      { console.log($1); return $1; }
    ;

expression_list
    : expression_list ',' e
      { $$ = $1.concat([$3]); }
    | e
      { $$ = [$1]; }
    ;

e
    : e '*' e
        {$$ = $1*$3;}
    | '(' e ')'
        {$$ = $2;}
    | NUMBER
        {$$ = Number(yytext);}
    | NAME '(' expression_list ')'
        {$$ = funcs[$NAME].apply(undefined, $expression_list);}
    ;

Answer 2

您需要在expression_list的第一个生产中执行操作。 默认操作只是将$1复制到$$ ，这意味着将丢弃附加的值。