如何在文本文件中获取某个字符串

Question

这是一个名为“sample.txt”的示例文本文件：

This is a sample text file and I need to return this string > "myScript.sql".
And this another string: "myNewScript.sql"
How do I do it using VBScript?

我想要做的是使用VB脚本返回“myScript.sql”和“myNewScript.sql”字符串。

喜欢：

If string's file extension =  ".sql"
  THEN
    myString = Scan left and get the string until the QUOTE (") symbol.
    Echo myString

这样的事情。

Answer 1

在这种情况下，您可以轻松使用正则表达式：

Set objFSO = CreateObject("Scripting.FileSystemObject") 
Set file = objFSO.OpenTextFile("sample.txt" , ForReading)  
Const ForReading = 1

Dim re
Set re = new regexp 
re.Pattern = """(\w+?[.]sql)"""
re.IgnoreCase = True
re.Global = True

Dim line
Do Until file.AtEndOfStream
    line = file.ReadLine
    For Each m In re.Execute(line)
       Wscript.Echo m.Submatches(0)
    Next
Loop 

通过以下方式执行：

cscript //nologo test.vbs

使用文件sample.txt：

This is a sample text file and I need to return this string > "myScript.sql".
And this another string: "myNewScript.sql"
How do I do it using VBScript?

你会得到这个：

myScript.sql
myNewScript.sql

Answer 2

Option Explicit

Const ForReading = 1

Dim fso
    Set fso = WScript.CreateObject("Scripting.FileSystemObject")

Dim fileMatch
    With New RegExp
        .Pattern = """([^""]*\.sql)"""
        .IgnoreCase = True
        .Global = True
        For Each fileMatch in .Execute(fso.OpenTextFile("sample.txt", ForReading).ReadAll())
            WScript.Echo fileMatch.SubMatches(0)
        Next 
    End With

这将在文件内容中搜索以.sql结尾的引用字符串，从而提取引号内的文本