具有多个条件的INDEX / MATCH

Question

需要有关Excel公式的帮助。

我正在尝试获取范围的摘要。 我一直在使用Match，Index，Countif函数，可以创建唯一日期列表，然后使用vlookup返回人员名称。

我需要考虑人员名称，因此如果2个人出现相同的日期，则在输出中显示为2行不同。

请参见下表-A＆B是输入，D＆E是我目前可以得到的，G＆H是我想要的输出。

提前致谢。

       A        B       C       D       E      F     G         H
1   13/01/15  RYAN           13/01/15  RYAN        13/01/15   RYAN
2   13/01/15  RYAN           14/01/15  RYAN        14/01/15   RYAN
3   14/01/15  RYAN           15/01/15  RYAN        14/01/15   FRANK
4   14/01/15  RYAN                                 15/01/15   RYAN
5   14/01/15  RYAN
6   14/01/15  RYAN
7   14/01/15  FRANK
8   14/01/15  FRANK
9   14/01/15  FRANK
10  15/01/15  RYAN
11  15/01/15  RYAN

我对Excel的所有自学知识都感谢诸如stackoverflow之类的论坛，所以对您的帮助将不胜感激。

Answer 1

实现此目的最简单的方法是使用数据透视表。 在A列和B列中添加标签（例如，日期和名称），然后选择A：B，INSERT，表-数据透视表，在“现有工作表”或“新建工作表”中选择位置，然后将“日期”和“名称”（下面）拖到ROWS中。

根据需要重新格式化。

Answer 2

我更喜欢数组公式的样式，它要求在第一个公式的正上方有一个未使用的单元格，以避免循环引用。 此未使用的单元格可用作列标题标签。

D2：E2中使用的数组公式¹为，

=IFERROR(INDEX(A:A, MATCH(0, COUNTIFS(D$1:D1,A$1:INDEX(A:A, MATCH(1E+99, A:A))&"",
                                      E$1:E1,B$1:INDEX(B:B, MATCH(1E+99, A:A))&""), 0)), "")
=IFERROR(INDEX(B:B, MATCH(0, COUNTIFS(D$1:D1,A$1:INDEX(A:A, MATCH(1E+99, A:A))&"",
                                      E$1:E1,B$1:INDEX(B:B, MATCH(1E+99, A:A))&""), 0)), "")

根据需要填写。 这些数组公式的最活跃查找范围在A列的最后一个日期所在的行中被动态截断，以将计算周期减少到最小。

我在示例数据列表的底部为Frank添加了一个额外的条目，以进一步演示双重唯一查询。

---

¹ _{数组公式需要使用Ctrl + Shift + Enter↵完成 。 如果输入正确，Excel会将公式用大括号括起来（例如{和} ）。 您不要在自己中键入大括号。 正确输入第一个单元格后，就可以像填充其他公式一样向下或向右填充或复制它们。 尝试将全列引用减少到更接近代表实际数据范围的范围。 数组公式对数地缩短了计算周期，因此，最好将参考范围缩小到最小。 有关更多信息，请参见准则和数组公式示例 。}

Answer 3

使用辅助列可以在没有任何数组公式的情况下实现。 这个想法是首先获取日期和名称的串联，然后仅获取列表中第一个出现的date＆name的行号，获取没有重复的那些行号，最后从A：A和B获取这些行号的INDEX。 ：B。

公式：

D1:D13  =A1&B1
E1:E13  =IF($D1<>"",MATCH($D1,$D:$D,0),"empty")
F1      =MIN($E:$E)
F2:F13  =LARGE($E:$E,COUNTIF($E:$E,">"&$F1))
H1:H13  =INDEX($A:$A,$F1)
I1:I13  =INDEX($B:$B,$F1)