哪种方法更适合处理PL / SQL中的丢失数据

Question

我有一些表，当指定过滤器的记录存在时，尝试获取主键，否则我需要我的函数返回NULL值。

我可以这样

function getIdIfExists(pParam number) return number is
  resultId number;
begin
  begin
    select ID into resultId from mytable where some_condition = pParam and rownum = 1;
    exception when NO_DATA_FOUND then
       resultId := NULL;
  end;

  return resultId;
end;

或者这样：

function getIdIfExists(pParam number) return number is
  resultId number := NULL;
begin
  for item in (select * into resultId from mytable where some_condition = pParam) loop
    resultId := item.ID;
    exit;
  end loop;
  return resultId;
end;

那么哪个更好呢？ 还是可能有其他方法？

Answer 1

如果有多个行符合条件，则第一个示例将引发TOO_MANY_ROWS异常。 第二个示例将遍历与条件匹配的所有行，并返回最后一个的ID。 您可以选择自己喜欢的行为。

分享并享受。

Answer 2

第一个（使用SQL而不是循环）要好得多，因为您正在利用SQL引擎搜索数据，而不是使用PL / SQL手动检查表中的每一行。 使用PL / SQL时的基本规则是，如果您可以在SQL中执行此操作，则不要在PL / SQL中执行。

但是，您的第一个示例将需要修改以使用诸如MAX之类的聚合函数，以确保仅返回一行，否则多行将引发异常。

这是我的处理方式：

FUNCTION getIdIfExists(p_id NUMBER) RETURN NUMBER
IS
   resultId NUMBER;
BEGIN
   SELECT   MAX(id)
   INTO     resultId
   FROM     mytable
   WHERE    some_condition = p_id;

   RETURN resultId;
END;

编辑：我实际上误读了第二个示例，并且没有看到您那里有WHERE子句。 鉴于此，第二个示例实际上是错误的，因为它没有ORDER BY，因此给定多个匹配项，SQL引擎可能会在多次执行中针对同一输入返回不同的结果。 第一个示例（修改为使用聚合函数）仍然是实现所需目标的一种更简洁的方法。

Answer 3

因此，如果您的问题是，哪种SQL样式比看看下面的实验要快：该代码片段以三种不同的方式循环10000 x“从双重选择虚拟对象”：

1. 显式游标
2. 隐式游标
3. 选择...进入...（实际上也是一个隐式游标）

这是代码：

procedure cursor_style_compare is
    l_start_time number;
    l_duration   number;
    l_dummy      dual.dummy%type;

    cursor c_explicit is
        select dummy from dual;
 begin
    -- Explicit Cursors:
    l_start_time := dbms_utility.get_time;
    for i in 1 .. 10000 loop
        for c1 in c_explicit loop
            null;
        end loop;
    end loop;
    l_duration := dbms_utility.get_time - l_start_time;
    dbms_output.put_line('Explicit Cursor:     ' || to_char(l_duration));

    -- Implicit Cursors (1):
    l_start_time := dbms_utility.get_time;
    for i in 1 .. 10000 loop
        for c1 in (select dummy from dual) loop
            null;
        end loop;
    end loop;
    l_duration := dbms_utility.get_time - l_start_time;
    dbms_output.put_line('Implicit Cursor (1): ' || to_char(l_duration));

    -- Implicit Cursors (2):
    l_start_time := dbms_utility.get_time;
    for i in 1 .. 10000 loop
        select dummy into l_dummy from dual;
    end loop;
    l_duration := dbms_utility.get_time - l_start_time;
    dbms_output.put_line('Implicit Cursor (2): ' || to_char(l_duration));

end;

如果在本地数据库（Windows Server上的Oracle 11.2 SE）上运行此代码，则结果为：

Explicit Cursor:     43
Implicit Cursor (1): 41
Implicit Cursor (2): 31

因此，如果结果仅是一行，则简单的“选择...放入...”是获取数据的最快方法。 这也是Oracle的官方建议： 使用游标（由Steven Feuerstein撰写）