我正在使用Antlr语法DECAF创建DECAF的解析器； 

//********* LEXER ******************
LETTER: ('a'..'z'|'A'..'Z') ;
DIGIT : '0'..'9' ;
ID : LETTER( LETTER | DIGIT)* ;
NUM: DIGIT(DIGIT)* ;
COMMENTS: '//' ~('\r' | '\n' )*  -> channel(HIDDEN);
WS : [ \t\r\n\f | ' '| '\r' | '\n' | '\t']+  ->channel(HIDDEN); 

CHAR: (LETTER|DIGIT|' '| '!' | '"' | '#' | '$' | '%' | '&' | '\'' | '(' | ')' | '*' | '+' 

| ',' | '-' | '.' | '/' | ':' | ';' | '<' | '=' | '>' | '?' | '@' | '[' | '\\' | ']' | '^' | '_' | '`'| '{' | '|' | '}' | '~' 
'\t'| '\n' | '\"' | '\'');


// ********** PARSER *****************

program : 'class' 'Program' '{' (declaration)* '}'  ;

declaration: structDeclaration| varDeclaration | methodDeclaration  ;

varDeclaration: varType ID ';' | varType ID '[' NUM ']' ';'  ;

structDeclaration : 'struct' ID '{' (varDeclaration)* '}'  ;

varType: 'int' | 'char' | 'boolean' | 'struct' ID | structDeclaration | 'void'  ;

methodDeclaration : methodType ID '(' (parameter (',' parameter)*)* ')' block  ;

methodType : 'int' | 'char' | 'boolean' | 'void' ;

parameter : parameterType ID | parameterType ID '[' ']' ;

parameterType: 'int' | 'char' | 'boolean'  ;

block : '{' (varDeclaration)* (statement)* '}' ;

statement : 'if' '(' expression ')' block ( 'else' block )? 
           | 'while' '(' expression ')' block
           |'return' expressionA ';' 
           | methodCall ';' 
           | block  
           | location '=' expression 
           | (expression)? ';'  ;

expressionA: expression | ;


location : (ID|ID '[' expression ']') ('.' location)?  ;

expression : location | methodCall | literal | expression op expression | '-' expression | '!' expression | '('expression')'  ;

methodCall :    ID '(' arg1 ')' ;

arg1    :   arg2 | ;

arg2    :   (arg) (',' arg)* ;

arg :   expression;

op: arith_op | rel_op | eq_op | cond_op  ;

arith_op : '+' | '-' | '*' | '/' | '%' ;

rel_op : '<' | '>' | '<=' | '>=' ;

eq_op : '==' | '!=' ;

cond_op : '&&' | '||' ;

literal : int_literal | char_literal | bool_literal ;

int_literal : NUM ;

char_literal : '\'' CHAR '\'' ;

bool_literal : 'true' | 'false' ;

当我输入时： 

    class Program {

    void main(){

        return 3+5 ;
    }
    }

解析树无法正确构建，因为它无法将3 + 5识别为表达式。 我的语法是否有引起问题的错误？

#1楼 票数：2 已采纳

Lexer规则从上到下匹配。 当2个或更多lexer规则匹配相同数量的字符时，首先定义的一个将获胜 。 因此，一位整数将作为DIGIT而不是NUM匹配。

尝试解析以下内容： 

class Program {
    void main(){    
        return 33 + 55 ;
    }
}

将被解析就好了。 这是因为33和55 被匹配为NUM ，因为NUM现在可以匹配2个字符（ DIGIT仅1个字符，所以NUM wins ）。

要修复此问题，请使DIGIT成为片段（以及LETTER ）： 

fragment LETTER: ('a'..'z'|'A'..'Z') ;
fragment DIGIT : '0'..'9' ;
ID : LETTER( LETTER | DIGIT)* ;
NUM: DIGIT(DIGIT)* ;

Lexer片段仅由其他lexer规则在内部使用，并且永远不会成为其自身的标记。

还有两件事：您的WS规则匹配得太多（现在也匹配了|和' ），应该是： 

WS : [ \t\r\n\f]+  ->channel(HIDDEN);

而且您不应该在解析器中匹配char文字：在lexer中进行匹配： 

CHAR : '\'' ( ~['\r\n\\] | '\\' ['\\] ) '\'';

否则，将无法正确解析以下内容： 

class Program {
    void main(){
        return '1';
    }
}

因为1将被标记为NUM而不是CHAR 。

  ask by Pablo Estrada translate from so

未解决问题？本站智能推荐：

1回复

在Antlr4中解析Decaf语法

我正在为用 ANTLR4 编写的 Decaf 编程语言创建解析器和词法分析器规则。 我正在尝试运行一个解析器测试文件，通过在终端窗口上打印访问过的节点并将它们粘贴到D3_parser_tree.html类中来获取解析器树。 根据此测试文件，当前解析器树缺少带有数字 10 的右方括号： class p
1回复

ANTLR语法-解析标签和说明

我正在写一个使用指令列表代码的解释器。 尝试为带有标签的指令编写语法时遇到一些问题。 我想解析此代码块： 如您所见，这些标签在一行中没有指令，但是我要解析的语言允许一行中的“标签+指令”。 因此，指令和标签有三种不同的组合： 指令 标签： 标签：说明 我可以解析
1回复

从ANTLR语法剥离动作会更改其解析算法

我有一个语法Foo.xtext （太复杂，无法在此处包含它）。 Xtext从中生成InternalFoo.g 。 进行一些调整后，它还会生成DebugInternalFoo.g ，它声称是相同的东西，没有任何动作。 现在，我直接用ANTLR剥离动作 我希望三个语法在检查它们时表现相同。
1回复

ANTLR：从不同的语法中调用规则

是否可以从不同的语法中调用规则？ 目的是在同一个文件中使用两种语言，第二种语言以（begin ...）开头，其中......是第二种语言。 语法应调用另一种语法来解析第二种语言。 例如：
2回复

ANTLR：在语法中定义新通道

我知道可以在ANTLR语法的默认令牌通道和隐藏令牌通道之间进行切换，但是可以说我想要第三个通道。 如何在gramar中定义新的令牌通道？ 例如，假设我想要一个名为ALTERNATIVE的频道。
1回复

ANTLR语法中的SpreadsheetFixedCell参考（$a$1，$a1，a$1等）问题

我正在为网络电子表格编辑功能，需要识别单元格引用，范围引用，然后根据需要为它们着色。 我能够识别和着色单元格引用，但无法识别固定的单元格引用（$ a $ 1，$ a1，a $ 1等...），因为在输入美元（'$'）符号后抛出错误。谁可以帮我这个事。 当我尝试将单元格引用输入为“ $ A $
1回复

C＃中的antlr语法/解析器无效的转换问题

我正在使用Anlr 3.5从下面包含的语法生成解析器和词法分析器。 该语法用于读取字符串，以便将它们转换为对象图形以供以后评估。 但是当我尝试使用unaryExpression子句时，我遇到了问题，这样做会抛出一个类转换异常报告： 无法将类型为'operandExpression_re
1回复

解析时出现antlr4语法错误

我有以下语法： 我需要解析的文本如下所示 我需要分割此文本，但运行grun.bat Token prog -gui -trace -diagnostics时会出现一些错误grun.bat Token prog -gui -trace -diagnostics 我的语法有什么问题？