在 Excel 中，我可以使用超链接运行 vba 宏吗？

Question

我有一个包含多行数据的电子表格。 我希望能够单击将使用该行中的数据运行宏的单元格。 由于行数总是在变化，我认为每行的超链接可能是最好的方法。

   ROW MeterID   Lat    Long   ReadX  ReadY  ReadZ   CoeffA  CoeffB  CoeffC
   2   10f62gs   34.1   33.3   102.2  231.3  382.2   4.34    22.1    0.002
   3   83gs72g   34.4   31.4   109.2  213.1  372.1   2.23    12.7    0.023
   4   43gS128   33.3   32.2   118.8  138.7  241.8   1.94    5.08    0.107

有没有办法通过单击超链接运行 vba 宏并能够知道单击超链接的单元格的行？

Answer 1

这对你有用

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
        MsgBox "Row " & ActiveCell.Row & " is clicked"
End Sub

Answer 2

是的，您可以，请按照以下简单步骤操作：

1. 选择要制作超链接的单元格
2. 右键单击-> 超链接...
3. 输入您正在制作超链接的同一单元格的地址，并为链接命名。 见下图：

将宏分配给超链接

4. 单击确定。
5. 超链接已创建。

注意：单击此超链接不会执行任何操作，因为它已分配给相同的单元格地址。

6. 现在按 Alt + F11
7. 复制粘贴下面的代码

通过单击超链接运行 Excel 宏

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)  
    'Check if the Target Address is same as you have given  
    'In the above example i have taken A4 Cell, so I am  
    'Comparing this with $A$4  
  
    If Target.Range.Address = "$A$4" Then  
        'Write your all VBA Code, which you want to execute  
        'Or Call the function or Macro which you have  
        'written or recorded.  
        MsgBox "Write your Code here to be executed"  
        Exit Sub  
    End If  
End Sub  

在上面的代码中，我们正在比较单元格地址，然后执行一组代码或函数。 还有另一种方法可以做到这一点。 我们可以与目标名称进行比较并执行代码。 在上面的示例中，我将超链接目标的名称指定为 MyMacro。

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)  
    'Check if the Target Name is same as you have given  
    'In the above example i have given the Name of the HyperLink  
    'is MyMacro.  
  
    If Target.Name = "mymacro" Then  
        'Write your all VBA Code, which you want to execute  
        'Or Call the function or Macro which you have  
        'written or recorded.  
        MsgBox "Write your Code here to be executed"  
        Exit Sub  
    End If  
End Sub  

Answer 3

运行宏的更有趣的超链接方式，看起来是下一个方法（超链接公式）。 它不需要任何事件：

1. 在单元格中编写超链接公式。 这也可以在 VBA 中完成：

    Sub testCreateHyperlinkFunction()
       'Very important to have # in front of the function name!
       Range("A1:A5").Formula = "=HYPERLINK(""#MyFunctionkClick()"", ""Run a function..."")"
    End Sub

一个更壮观的用途是下一个方法，能够保留处理范围的初始单元格值（例如“A1：A5”）：

Sub testCreateHyperlinkFunctionBis()
  Dim rng As Range, arr As Variant, c As Range, i As Long
   Set rng = Range("A1:A5")
   arr = rng.Value
   For i = 1 To UBound(arr, 1)
     Range("A" & i).Formula = "=HYPERLINK(""#MyFunctionkClick()"", " & _
            IIf(IsNumeric(arr(i, 1)), arr(i, 1), """" & arr(i, 1) & """") & ")"
   Next i
End Sub

2. 创建要调用的函数（在模块中）：

    Function MyFunctionkClick()
      Set MyFunctionkClick = Selection 'Do not miss this part!
      MsgBox "The clicked cell addres is " & Selection.row
    End Function

3. 单击单元格，函数MyFunctionkClick()运行...

Answer 4

我只想添加另一种方法，其灵感来自于我过去使用过的答案之一。 这意味着您不必创建超链接或辅助列来启动处理该行，您只需双击要处理的行中的任何单元格：

在你想要双击工作的工作表上，使用这个：

Private Sub Worksheet_Activate()
Application.OnDoubleClick = "Module1.ProcessRow"
End Sub

Private Sub Worksheet_Deactivate()
Application.OnDoubleClick = ""
End Sub

然后在Module1有一个例程来处理活动单元格：

Sub processRow()
MsgBox "Row " & ActiveCell.Row & " on " & ActiveSheet.Name & " was clicked"
End Sub

您还应该在工作簿事件中禁用 Excel 双击方法：

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Application.OnDoubleClick = ""
End Sub

我发现双击方法对于很多过程来说真的非常方便和直观，例如调出一个用户窗体，其中包含从行填充的数据，或者将该数据传输到另一个可能带有计算或格式等的工作表。

Answer 5

我认为与其为每个单元格创建超链接的麻烦，不如创建一个引用Activecell属性的宏。 接下来，为要运行的宏创建键盘快捷键。 这样做：

1. 按 ALT+F8
2. 选择Options
3. 选择一个键作为快捷键

如果您已经有超链接，最好使用Hyperlink_Follow事件触发宏。 如果没有，请考虑我的建议。

Answer 6

刚刚使用 =HYPERLINK() 方法并发现，此代码将用于在 Excel 单元格中创建超链接：

Sub testCreateHyperlinkFunction()
    Dim r As Range
    Set r = Range("A1")
    ' use SubAddress arg of Hyperlinks.Add method to link our function
    r.Hyperlinks.Add _
        Anchor:=r, _
        Address:=vbNullString, _
        SubAddress:="MyFunctionkClick()", _
        TextToDisplay:="Hyperlink text" 

    ' note: TextToDisplay arg is desirable here, 
    ' otherwise Excel will insert MyFunctionkClick() here

End Sub

Function MyFunctionkClick()
  Set MyFunctionkClick = Selection ' required!
  MsgBox "The clicked cell addres is " & Selection.row
End Function

好处：

• Range.Hyperlinks(1).Follow 作品；
• 防止用户不必要的链接更改；
• 与文档中的其他链接统一“查看和填充”；

缺点：

• MyFunctionkClick() 的调试仍然不可用；
• 无法从 Excel GUI 更改超链接 - 只能从代码更改；

Answer 7

尝试使用由超链接调用的 VBA 宏。
它的任务是在包含 =HYPERLINK 的行下方插入一行。
VBA 似乎忽略了。插入

Function HyperlinkFnc_AddRow()
  Set HyperlinkFnc_AddRow = Selection
  MsgBox "Next line of code: Adding a row below selected row " & Selection.Row
  Rows(Selection.Row + 1).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromLeftOrAbove
End Function

Sub Button_AddRow()
  ActiveSheet.Shapes(Application.Caller).TopLeftCell.Select
  HyperlinkFnc_AddRow
End Sub

观察
当超链接调用 HyperlinkFnc_AddRow() 时 function
（例如 =HYPERLINK("#HyperlinkFnc_AddRow()";"通过此超链接调用 Function ""HyperlinkFnc_AddRow()"" 应在下方添加行））：

1. “MsgBox”获得控制权。
2. 以下带有“.Insert”的行被忽略（未插入一行）。

通过按钮调用 Sub Button_AddRow() 显示，function“HyperlinkFnc_AddRow”中的代码按预期工作（插入一行）。
解决这个问题会很有帮助。