如何在不删除现有数据的情况下以新格式将数据追加到现有剪贴板？

Question

我需要以几种格式将数据放在剪贴板上，一种是RTF。 我正在使用的组件可以很好地处理RTF以外的所有内容。 如何追加RTF格式的数据而又不丢失祖先类已经放置在其中的数据？ 如果可以的话，我试图避免从复制到剪贴板例程的祖先中复制剪贴板逻辑。

Answer 1

您可以通过执行以下操作将附加到现有剪贴板数据中：

1. 呼叫Clipboard.Open 。
2. 调用将其他数据放在剪贴板上的基类方法。
3. 调用SetClipboardData传递给Clipboard.SetAsHandle或SetClipboardData 。
4. 呼叫Clipboard.Close 。

只要继承的呼叫在您的“ Open/Close对中，您便会获得所需的效果。

这是我的意思的证明：

procedure SetBuffer(Format: Word; const Buffer; Size: Integer);
var
  DataPtr: Pointer;
  Data: THandle;
begin
  Data := GlobalAlloc(GMEM_MOVEABLE+GMEM_DDESHARE, Size);
  try
    DataPtr := GlobalLock(Data);
    try
      Move(Buffer, DataPtr^, Size);
      Win32Check(SetClipboardData(Format, Data) <> 0);
    finally
      GlobalUnlock(Data);
    end;
  except
    GlobalFree(Data);
    raise;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Bitmap: TBitmap;
const
  Text: string = 'foo';
begin
  Clipboard.Open;
  try

    // imagine this next block is the base component's method to set the clipboard 
    Clipboard.Open;
    try
      Bitmap := GetFormImage;
      try
        Clipboard.Assign(Bitmap);
      finally
        Bitmap.Free;
      end;
    finally
      Clipboard.Close;
    end;

    // once that is done, we can add out extra data    
    SetBuffer(CF_UNICODETEXT, Text[1], ByteLength(Text));
  finally
    Clipboard.Close;
  end;
end;

因为我们一直都在剪贴板上保持锁，所以没有其他进程会妨碍我们。 基本组件方法将在开始添加其文本之前清空剪贴板。