Perl数据处理

Question

我有类似下面的数据：

$data = [
    [qw(x y)],
    [qw(x)  ],
    [qw(x z)],
    [qw(z)  ], 
];

我想将其转换为如下所示：

 [ x, x, x, z ]

规则从第一个元素开始，找到前两个元素之间的公共元素，如果找到任何公共元素，则将共同值分配给两个元素iex现在选择第二个和第三个元素，找到它们之间是否有任何共同值，然后执行相同并继续，直到到达最后一个元素。 如果您发现最后两对之间有相同的值，则仅将其分配给最后一个元素。

Answer 1

听起来您想计算某种数据点的交集？ 我会做这样的事情：

#!/usr/bin/env perl
use strict; use warnings;
use autodie;

use Data::Dumper;

my @data = (
    [qw(x y)],
    [qw(x)  ],
    [qw(x z)],
    [qw(z)  ],
);

sub intersect {
    my ($a, $b) = @_;

    my $union = {};
    my $isect = {};

    foreach my $e (@$a, @$b) {
        $union->{$e}++ && $isect->{$e}++;
    }

    return keys %$isect;
}

my @result = ();

for my $i (0..$#data - 1) {
    my @intersection = intersect($data[$i], $data[$i+1]);

    if (scalar @intersection) {
        my $isect = shift @intersection;

        if ($i == 0) {
            push @result, $isect;
        }

        push @result, $isect;
    }
    else {
        die sprintf("Data points do not intersect at position %d", $i+1);
    }
}

print Dumper \@result;

运行此脚本将为我提供以下输出：

$ ./intersection.pl 
$VAR1 = [
          'x',
          'x',
          'x',
          'z'
        ];

希望这可以帮助。

CPAN的Array::Utils包中还提供了另一种intersect方法。

Answer 2

使用Array::Utils模块中的intersect函数可以轻松完成此操作。 由于它不是核心模块，因此可能需要安装。

我不确定我是否正确地指定了您的规格。 您想在头两个列表之间添加两次相同的公共元素。 那正确吗？ 而且，如果两对列表之间有多个公共项目，那么您不会说会怎样。 此解决方案仅添加第一个。

use strict;
use warnings;

use Array::Utils 'intersect';

my $data = [ ['x', 'y'], ['x'], ['x', 'z'], ['z'] ];

my @result;

for my $i ( 1 .. $#$data ) {
  my @pair = @{$data}[$i-1, $i];
  my @common = intersect(@{$pair[0]}, @{$pair[1]});
  push @result, $common[0];
  push @result, $common[0] if $i == 1;
}

printf "[ %s ]\n", join ', ', @result;

输出

[ x, x, x, z ]

---

更新资料

如果安装模块时遇到问题，则可以简单地将此子例程定义复制到代码末尾，然后删除use Array::Utils语句。

sub intersect(\@\@) {
  my %e = map { $_ => undef } @{$_[0]};
  return grep { exists( $e{$_} ) } @{$_[1]};
}