如何在构造函数运行后设置CreateParams？

Question

  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  end;

  TForm2 = class(TForm)
  private
    FAppWindow: Boolean;
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  public
    property AppWindow: Boolean read FAppWindow write FAppWindow;
  end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Form2 := TForm2.Create(Self);
  Form2.AppWindow := True;
  Form2.Show;
end;

procedure TForm2.CreateParams(var Params: TCreateParams);
begin
  inherited;
  if FAppWindow then begin
    Params.Style := Params.Style or WS_EX_APPWINDOW;
    Params.WndParent := 0;
  end;
end;

这不起作用，因为窗口句柄是在TForm的构造函数期间创建的，因此CreateParams运行得太早而FAppWindow始终为False 。

编写自定义构造函数也不起作用，因为在将任何数据保存到实例之前，必须最终调用创建句柄的继承构造函数：

constructor TForm2.CreateAppWindow(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FAppWindow := True;
end;

有办法：

• 延迟窗口句柄的创建？
• 创建窗口句柄后改变窗口样式？
• 构造函数运行后重新创建窗口句柄？
• 还有其他一些我没想过的选择呢？

如何从课堂的“外部”改变表格的风格？

Answer 1

最简单的解决方案是将参数传递给构造函数中的表单，而不是等到它完成创建。

这意味着你需要为TForm2引入一个构造函数，它接受你需要在CreateParams传递的任何信息作为参数。

在调用继承的构造函数之前记下任何状态。 此外，当您将所有者设置为零时，无需设置WS_EX_APPWINDOW 。

Answer 2

Delphi的好处是派生的构造函数不必将inherited构造函数作为其第一个语句。 所以你可以先设置你的FAppWindow成员，然后调用inherited构造函数来流式传输DFM并创建窗口，例如：

procedure TForm1.FormCreate(Sender: TObject);
begin
  Form2 := TForm2.CreateAppWindow(Self);
  Form2.Show;
end;

constructor TForm2.CreateAppWindow(AOwner: TComponent);
begin
  FAppWindow := True;
  inherited Create(AOwner);
end;

Answer 3

这似乎有助于重新创建句柄，我从RecreateAsPopup VCL方法得到了这个想法：

procedure TForm2.SetAppWindow(const Value: Boolean);
begin
  FAppWindow := Value;
  if HandleAllocated then
    RecreateWnd
  else
    UpdateControlState;
end;