一段代码只有在多次运行时才能按预期工作

Question

目前，我正在调试一段代码。 目前，我的代码按预期工作，它为finaldate变量分配了日期，然后在代码中查找以删除所有高于finaldate变量的日期。 唯一的问题是子过程需要多次运行才能生效。 例如，当我运行它一次删除了大约一半的日期，然后再次运行它并且执行相同的操作时，我通常会按F5大约5次以确认其完成。 尽管这在调试中很好，但我需要知道它每次都能完美运行。

Sub Remove_Unecessary_Data_1()

Dim ALLCs As Worksheet
Dim DS As Worksheet
Dim finaldate As Date




Set DS = Sheets("Data Summary")
Set ALLCs = Sheets("Asset LLC (Input)")



    ALLCs.Select
        For y = 1 To 40
            If InStr(1, Cells(13, y), "Timestamp of Execution") Then
                finaldate = ALLCs.Cells(50, y)
            End If
        Next

    ALLCs.Select
        For u = 1 To 40
            If InStr(1, Cells(13, u), "Start Date") Then
                For p = 2 To 69584
                If Cells(p + 14, u) > finaldate Then
                Cells(p + 14, u).EntireRow.Delete
                End If
                Next
            End If
        Next
  end sub

编辑：样本数据

单元格（50，y）= 15/12/15最终日期=单元格（50，Y）

标题为“开始日期”的列中包含的日期范围为1/05/15到15/1/30。

如果工作正常，则15年1月12日之后的所有日期都应取消整行。

Answer 1

删除行时，必须从下到上进行操作，否则最终将跳过行。

例如，您有：

 Line 1
>Line 2
 Line 3
 Line 4

当您删除代码的Line 2行时，原来的“行” 3现在变成了“行” 2，但是您的代码继续前进以查看Line 4 。 您的数据现在看起来像这样：

 Line 1
 Line 3
 >Line 4

如果您更改了这段代码：

For p = 2 To 69584
  If Cells(p + 14, u) > finaldate Then
    Cells(p + 14, u).EntireRow.Delete
  End If
Next

对此：

For p = 69598 to 16 step - 1
  If Cells(p, u) > finaldate Then
    Cells(p, u).EntireRow.Delete
  End If
Next

一切都应该没问题。

*注意：我将起点和终点调高了14，并从Cells()引用中删除了+ 14 。 在那儿做额外的数学毫无意义...

Answer 2

使用以下命令删除行时：

Cells(p + 14, u).EntireRow.Delete

删除行下面的行将向上移动以占据该空间。 如果该行包含应删除的日期，则它将被忽略，因为计数器会自动移到下一行。 例如，假设我们希望删除“ Data列中所有带有C或D的行：

Row Number    Data
1             A
2             B
3             C    
4             D
5             E

变成：

Row Number    Data
1             A
2             B
3             D
4             E

该行计数器移至4而不检查3中的新值，因此不会删除D

您可以通过将If...Then语句更改为Do...While循环来解决此问题：

Sub Remove_Unecessary_Data_1()

Dim ALLCs As Worksheet
Dim DS As Worksheet
Dim finaldate As Date




Set DS = Sheets("Data Summary")
Set ALLCs = Sheets("Asset LLC (Input)")



    ALLCs.Select
        For y = 1 To 40
            If InStr(1, Cells(13, y), "Timestamp of Execution") Then
                finaldate = ALLCs.Cells(50, y)
            End If
        Next

    ALLCs.Select
        For u = 1 To 40
            If InStr(1, Cells(13, u), "Start Date") Then
                For p = 2 To 69584
                    Do While (Cells(p + 14, u) > finaldate)
                        Cells(p + 14, u).EntireRow.Delete
                    Loop
                Next
            End If
        Next
End sub

这应该在删除上一行之后继续检查该单元格，以确保也不应删除替换行。

Answer 3

当您删除行而行数增加时，您会错过分析刚删除的行之后的每一行的事实，因为行（i + 1）已变成行（i），但随着下一个。

这是考虑到您的代码（并摆脱了无用的Select ）

Sub Remove_Unecessary_Data_1()

Dim ALLCs As Worksheet, _
    DS As Worksheet, _
    FinalDate As Date

Set DS = Sheets("Data Summary")
Set ALLCs = Sheets("Asset LLC (Input)")

For y = 1 To 40
    If InStr(1, ALLCs.Cells(13, y), "Timestamp of Execution") Then
        FinalDate = ALLCs.Cells(50, y)
    End If
Next


For u = 1 To 40
    If InStr(1, ALLCs.Cells(13, u), "Start Date") Then
        For p = 69584 To 2 Step -1
        If Cells(p + 14, u) > FinalDate Then
            Cells(p + 14, u).EntireRow.Delete
        End If
        Next
    End If
Next
End Sub