Modelica：混合连接器和直接输入

Question

下面的Modelica包 - 既不是特别有用也不是有趣 - 不会产生任何警告。

package P
  connector C
    Real c;
  end C;
  model A
    input C x;
    output Real y;
  equation 
    y = x.c;
  end A;
  model B
    input C inp;
    output C out;
    A a;
  equation 
    a.x = inp;
    out.c = a.y;
  end B;
end P;

但是，当A在下列情况下不使用连接器时，会出现警告： 以下输入缺少绑定方程式： ax 。 显然， ax有一个约束方程。 为什么会有这样的警告？

package P
  connector C
    Real c;
  end C;
  model A
    input Real x;
    output Real y;
  equation 
    y = x;
  end A;
  model B
    input C inp;
    output C out;
    A a;
  equation 
    a.x = inp.c;
    out.c = a.y;
  end B;
end P;

Answer 1

这里的问题是没有一个具有约束力的等式。 只有一个普通的等式。 绑定方程是作为元素的修改而应用的方程，例如

model B
  input C inp;
  output C out;
  A a(x=inp.c) "Binding equation";
equation 
  out.c = a.y;
end B;

请注意，一般情况下，如果两个东西是连接器，它们不应该等同，它们应该连接。 这将有助于您避免此问题。 所以在你的第一个版本的B ：

model B
  input C inp;
  output C out;
  A a;
equation
  connect(a.x, inp); 
  out.c = a.y;
end B;

约束方程限制的原因与确保组件平衡有关。 您可以在规范或Modelica中通过示例了解更多相关信息。 通过使用它作为约束方程，它清楚地表明该方程可用于求解该变量（ 即，包含该变量的等式中的项不会消失或病态）。