在Fortran中读取整数列表文件

Question

我想使用Fortran程序读取数据文件，其中每一行都是整数列表。

每行都有可变数量的整数，由给定字符（空格，逗号...）分隔。

输入样例：

1,7,3,2
2,8
12,44,13,11

我有一个分割线的解决方案，我发现这很麻烦：

module split
    implicit none
contains
    function string_to_integers(str, sep) result(a)
        integer, allocatable :: a(:)
        integer :: i, j, k, n, m, p, r
        character(*) :: str
        character :: sep, c
        character(:), allocatable :: tmp

        !First pass: find number of items (m), and maximum length of an item (r)
        n = len_trim(str)
        m = 1
        j = 0
        r = 0
        do i = 1, n
            if(str(i:i) == sep) then
                m = m + 1
                r = max(r, j)
                j = 0
            else
                j = j + 1
            end if
        end do
        r = max(r, j)

        allocate(a(m))
        allocate(character(r) :: tmp)

        !Second pass: copy each item into temporary string (tmp),
        !read an integer from tmp, and write this integer in the output array (a)
        tmp(1:r) = " "
        j = 0
        k = 0
        do i = 1, n
            c = str(i:i)
            if(c == sep) then
                k = k + 1
                read(tmp, *) p
                a(k) = p
                tmp(1:r) = " "
                j = 0
            else
                j = j + 1
                tmp(j:j) = c
            end if
        end do
        k = k + 1
        read(tmp, *) p
        a(k) = p
        deallocate(tmp)
    end function
end module

我的问题 ：

• 在Fortran中，有没有更简单的方法可以做到这一点？ 我的意思是，在不知道要读取的值数量的情况下，读取值列表。 上面的代码看起来很尴尬，在Fortran中文件I / O看起来并不容易。

• 同样，主程序必须读取长度未知且无界的行。 如果我假设它们的长度都相同，那么我就能够读取它们（见下文），但是我不知道如何读取无界线。 我想它需要Fortran 2003的流功能，但是我不知道该怎么写。

这是当前程序：

program read_data
    use split
    implicit none
    integer :: q
    integer, allocatable :: a(:)
    character(80) :: line
    open(unit=10, file="input.txt", action="read", status="old", form="formatted")
    do
        read(10, "(A80)", iostat=q) line
        if(q /= 0) exit
        if(line(1:1) /= "#") then
            a = string_to_integers(line, ",")
            print *, ubound(a), a
        end if
    end do
    close(10)
end program

关于这个问题的评论：通常，我会在Python中执行此操作，例如，将line转换为a = [int(x) for x in line.split(",")]一样简单，读取文件也是如此几乎是一件微不足道的任务。 我将使用Fortran DLL进行“实际”计算。 但是，我想提高我在文件I / O方面的Fortran技能。

Answer 1

我并不是说这是最短的，但是比你的短得多。 一旦拥有它，就可以重用它。 我并不完全同意这些说法，Fotran在字符串处理方面有多不好，我在Fortran中很好地进行了令牌化，递归下降解析和类似工作，尽管在其他一些语言中，拥有更丰富的库更容易。 有时，您也可以使用在Fortran中以其他语言（尤其是C和C ++）编写的库。

如果您始终使用逗号，则可以删除逗号替换，从而将其缩短得更多。

function string_to_integers(str, sep) result(a)
    integer, allocatable :: a(:)
    character(*) :: str
    character :: sep
    integer :: i, n_sep

    n_sep = 0
    do i = 1, len(str)
      if (str(i:i)==sep) then
        n_sep = n_sep + 1
        str(i:i) = ','
       end if
    end do
    allocate(a(n_sep+1))
    read(str,*) a
end function

潜在缩短：查看str使用作为字符数组equivalence或transfer和使用count()的内部allocate得到的大小a 。

Answer 2

对于您的目标，我的答案可能太简单了，但是最近我花了很多时间阅读奇怪的数字文本文件。 我最大的问题是找到它们的起点（在您的情况下并不困难），然后我最好的朋友是列表导向的阅读器。

read(unit=10,fmt=*) a

将所有数据读入向量“ a”，完成交易。 使用这种方法，您将不知道任何数据来自哪一行。 如果要分配它，则可以读取一次文件，然后找出某种算法使数组大于所需大小，例如计算行数，并且知道每行的最大数据量（例如21）。

    status = 0
    do while ( status == 0)
      line_counter = line_counter + 1
      read(unit=10,, iostat=status, fmt=*)
    end do

allocate(a(counter*21))

如果要消除零值，则可以将其删除，或者如果不希望有零值，则可以在其前面填充负数“ a”，然后将所有这些值都删除。

来自其他建议的另一种方法是先对逗号进行计数，然后在循环受控制的位置进行读取

do j = 1, line_counter         ! You determined this on your first read
  read(unit=11,fmt=*) a(j,:)   ! a is now a 2 dimensional array (line_counter, maxNumberPerLine)
                               ! You have a separate vector numberOfCommas(j) from before
end do

现在，您可以对这两个数组执行任何操作，因为您知道所有数据，数据来自哪一行，每行有多少数据。